[Mlir-commits] [mlir] 17cb210 - [OpenMP][mlir] Add Groupprivate op in omp dialect. (#162704)
llvmlistbot at llvm.org
llvmlistbot at llvm.org
Sun May 3 23:22:28 PDT 2026
Author: Chaitanya
Date: 2026-05-04T11:52:24+05:30
New Revision: 17cb2106f6f8dc40d32e4c0027ed6d2a29b4b8ea
URL: https://github.com/llvm/llvm-project/commit/17cb2106f6f8dc40d32e4c0027ed6d2a29b4b8ea
DIFF: https://github.com/llvm/llvm-project/commit/17cb2106f6f8dc40d32e4c0027ed6d2a29b4b8ea.diff
LOG: [OpenMP][mlir] Add Groupprivate op in omp dialect. (#162704)
This PR adds omp.groupprivate mlir op to omp dialect.
The groupprivate directive specifies that variables are replicated, with
each group having its own copy. The operation takes a symbol reference
to a global variable and an optional device_type attribute, and returns
the address of its groupprivate copy.
Op representation:
`%gp = omp.groupprivate @global_var : !llvm.ptr`
`%gp = omp.groupprivate @global_var device_type(any) : !llvm.ptr`
LLVM IR translation:
On target devices (AMDGCN/NVPTX), the op is lowered to a new global
variable in the shared address space
On the host, the original global address is used as a fallback.
Added:
mlir/test/Target/LLVMIR/omptarget-groupprivate.mlir
Modified:
mlir/include/mlir/Dialect/OpenMP/OpenMPOps.td
mlir/lib/Dialect/OpenMP/IR/OpenMPDialect.cpp
mlir/lib/Target/LLVMIR/Dialect/OpenMP/OpenMPToLLVMIRTranslation.cpp
mlir/test/Dialect/OpenMP/ops.mlir
mlir/test/Target/LLVMIR/openmp-llvm.mlir
Removed:
################################################################################
diff --git a/mlir/include/mlir/Dialect/OpenMP/OpenMPOps.td b/mlir/include/mlir/Dialect/OpenMP/OpenMPOps.td
index cddbe4a318e69..7741542d3329e 100644
--- a/mlir/include/mlir/Dialect/OpenMP/OpenMPOps.td
+++ b/mlir/include/mlir/Dialect/OpenMP/OpenMPOps.td
@@ -2531,4 +2531,33 @@ def IteratorOp : OpenMP_Op<"iterator",
let hasVerifier = 1;
}
+//===----------------------------------------------------------------------===//
+// [6.0] groupprivate Directive
+//===----------------------------------------------------------------------===//
+
+def GroupprivateOp : OpenMP_Op<"groupprivate",
+ [Pure, DeclareOpInterfaceMethods<SymbolUserOpInterface>]> {
+ let summary = "groupprivate directive";
+ let description = [{
+ The groupprivate directive specifies that variables are replicated, with
+ each group having its own copy.
+
+ This operation takes a symbol reference to a global variable and returns
+ the address of its groupprivate copy. The referenced symbol must exist and
+ must not be a function.
+
+ The optional `device_type` attribute specifies where the groupprivate
+ storage should be allocated (host, nohost, or any).
+ }];
+
+ let arguments = (ins
+ FlatSymbolRefAttr:$sym_name,
+ OptionalAttr<DeclareTargetDeviceTypeAttr>:$device_type
+ );
+ let results = (outs OpenMP_PointerLikeType:$gp_addr);
+ let assemblyFormat = [{
+ $sym_name (`device_type` $device_type^)? `:` type($gp_addr) attr-dict
+ }];
+}
+
#endif // OPENMP_OPS
diff --git a/mlir/lib/Dialect/OpenMP/IR/OpenMPDialect.cpp b/mlir/lib/Dialect/OpenMP/IR/OpenMPDialect.cpp
index bb300c4afa562..c6683d1c23e09 100644
--- a/mlir/lib/Dialect/OpenMP/IR/OpenMPDialect.cpp
+++ b/mlir/lib/Dialect/OpenMP/IR/OpenMPDialect.cpp
@@ -5033,6 +5033,24 @@ LogicalResult IteratorOp::verify() {
return success();
}
+//===----------------------------------------------------------------------===//
+// GroupprivateOp
+//===----------------------------------------------------------------------===//
+
+LogicalResult
+GroupprivateOp::verifySymbolUses(SymbolTableCollection &symbolTable) {
+ auto *symbol = symbolTable.lookupNearestSymbolFrom(*this, getSymNameAttr());
+ if (!symbol)
+ return emitOpError() << "expected symbol reference '" << getSymName()
+ << "' to point to a global variable";
+
+ if (isa<FunctionOpInterface>(symbol))
+ return emitOpError() << "expected symbol reference '" << getSymName()
+ << "' to point to a global variable, not a function";
+
+ return success();
+}
+
#define GET_ATTRDEF_CLASSES
#include "mlir/Dialect/OpenMP/OpenMPOpsAttributes.cpp.inc"
diff --git a/mlir/lib/Target/LLVMIR/Dialect/OpenMP/OpenMPToLLVMIRTranslation.cpp b/mlir/lib/Target/LLVMIR/Dialect/OpenMP/OpenMPToLLVMIRTranslation.cpp
index 53020dc867926..846cc584c8843 100644
--- a/mlir/lib/Target/LLVMIR/Dialect/OpenMP/OpenMPToLLVMIRTranslation.cpp
+++ b/mlir/lib/Target/LLVMIR/Dialect/OpenMP/OpenMPToLLVMIRTranslation.cpp
@@ -34,7 +34,9 @@
#include "llvm/IR/IRBuilder.h"
#include "llvm/IR/MDBuilder.h"
#include "llvm/IR/ReplaceConstant.h"
+#include "llvm/Support/AMDGPUAddrSpace.h"
#include "llvm/Support/FileSystem.h"
+#include "llvm/Support/NVPTXAddrSpace.h"
#include "llvm/Support/VirtualFileSystem.h"
#include "llvm/TargetParser/Triple.h"
#include "llvm/Transforms/Utils/ModuleUtils.h"
@@ -8123,6 +8125,76 @@ convertFreeSharedMemOp(omp::FreeSharedMemOp freeMemOp,
return success();
}
+/// Converts an OpenMP groupprivate operation into LLVM IR.
+static LogicalResult
+convertOmpGroupprivate(Operation &opInst, llvm::IRBuilderBase &builder,
+ LLVM::ModuleTranslation &moduleTranslation) {
+ llvm::OpenMPIRBuilder *ompBuilder = moduleTranslation.getOpenMPBuilder();
+ auto groupprivateOp = cast<omp::GroupprivateOp>(opInst);
+
+ if (failed(checkImplementationStatus(opInst)))
+ return failure();
+
+ bool isTargetDevice = ompBuilder->Config.isTargetDevice();
+
+ // Determine whether group-private storage should be allocated based on
+ // device_type. When not specified, default to 'any' (allocate on both).
+ bool shouldAllocate = true;
+ switch (groupprivateOp.getDeviceType().value_or(
+ mlir::omp::DeclareTargetDeviceType::any)) {
+ case mlir::omp::DeclareTargetDeviceType::host:
+ shouldAllocate = !isTargetDevice;
+ break;
+ case mlir::omp::DeclareTargetDeviceType::nohost:
+ shouldAllocate = isTargetDevice;
+ break;
+ case mlir::omp::DeclareTargetDeviceType::any:
+ shouldAllocate = true;
+ break;
+ }
+
+ // Look up the global variable directly by symbol name.
+ LLVM::GlobalOp global = SymbolTable::lookupNearestSymbolFrom<LLVM::GlobalOp>(
+ &opInst, groupprivateOp.getSymNameAttr());
+ if (!global)
+ return opInst.emitError()
+ << "expected symbol '" << groupprivateOp.getSymName()
+ << "' to reference an LLVM global variable";
+
+ llvm::GlobalValue *globalValue = moduleTranslation.lookupGlobal(global);
+ llvm::Type *varType = moduleTranslation.convertType(global.getType());
+ std::string varName = globalValue->getName().str();
+
+ llvm::Value *resultPtr;
+ if (shouldAllocate && isTargetDevice) {
+ llvm::Module *llvmModule = moduleTranslation.getLLVMModule();
+ llvm::Triple targetTriple(llvmModule->getTargetTriple());
+ unsigned sharedAddressSpace;
+ if (targetTriple.isAMDGCN())
+ sharedAddressSpace = llvm::AMDGPUAS::LOCAL_ADDRESS;
+ else if (targetTriple.isNVPTX())
+ sharedAddressSpace = llvm::NVPTXAS::ADDRESS_SPACE_SHARED;
+ else
+ return opInst.emitError() << "groupprivate is not supported for target: "
+ << targetTriple.str();
+ llvm::GlobalVariable *sharedVar = new llvm::GlobalVariable(
+ *llvmModule, varType, /*isConstant=*/false,
+ llvm::GlobalValue::InternalLinkage, llvm::PoisonValue::get(varType),
+ varName, /*InsertBefore=*/nullptr, llvm::GlobalValue::NotThreadLocal,
+ sharedAddressSpace,
+ /*isExternallyInitialized=*/false);
+ resultPtr = sharedVar;
+ } else {
+ if (shouldAllocate && !isTargetDevice)
+ opInst.emitWarning("groupprivate directive is currently ignored on the "
+ "host, using original global");
+ resultPtr = globalValue;
+ }
+
+ moduleTranslation.mapValue(opInst.getResult(0), resultPtr);
+ return success();
+}
+
/// Given an OpenMP MLIR operation, create the corresponding LLVM IR (including
/// OpenMP runtime calls).
LogicalResult OpenMPDialectLLVMIRTranslationInterface::convertOperation(
@@ -8349,6 +8421,9 @@ LogicalResult OpenMPDialectLLVMIRTranslationInterface::convertOperation(
.Case([&](omp::FreeSharedMemOp op) {
return convertFreeSharedMemOp(op, builder, moduleTranslation);
})
+ .Case([&](omp::GroupprivateOp) {
+ return convertOmpGroupprivate(*op, builder, moduleTranslation);
+ })
.Default([&](Operation *inst) {
return inst->emitError()
<< "not yet implemented: " << inst->getName();
diff --git a/mlir/test/Dialect/OpenMP/ops.mlir b/mlir/test/Dialect/OpenMP/ops.mlir
index 925f6c5614899..6ece0e95cdce0 100644
--- a/mlir/test/Dialect/OpenMP/ops.mlir
+++ b/mlir/test/Dialect/OpenMP/ops.mlir
@@ -3957,3 +3957,30 @@ func.func @omp_free_shared_mem(%n: i64) {
omp.free_shared_mem [%n x f32 : (i64) align(32)] %1 : !llvm.ptr
return
}
+
+// CHECK-LABEL: func.func @omp_groupprivate_device_type
+func.func @omp_groupprivate_device_type() {
+ %1 = arith.constant 2 : i32
+
+ // CHECK: {{.*}} = omp.groupprivate @gp : !llvm.ptr
+ %group_private_addr = omp.groupprivate @gp : !llvm.ptr
+
+ // CHECK: {{.*}} = omp.groupprivate @any device_type (any) : !llvm.ptr
+ %group_private_any = omp.groupprivate @any device_type(any) : !llvm.ptr
+ llvm.store %1, %group_private_any : i32, !llvm.ptr
+
+ // CHECK: {{.*}} = omp.groupprivate @host device_type (host) : !llvm.ptr
+ %group_private_host = omp.groupprivate @host device_type(host) : !llvm.ptr
+ llvm.store %1, %group_private_host : i32, !llvm.ptr
+
+ // CHECK: {{.*}} = omp.groupprivate @nohost device_type (nohost) : !llvm.ptr
+ %group_private_nohost = omp.groupprivate @nohost device_type(nohost) : !llvm.ptr
+ llvm.store %1, %group_private_nohost : i32, !llvm.ptr
+
+ return
+}
+
+llvm.mlir.global internal @gp() : i32
+llvm.mlir.global internal @any() : i32
+llvm.mlir.global internal @host() : i32
+llvm.mlir.global internal @nohost() : i32
diff --git a/mlir/test/Target/LLVMIR/omptarget-groupprivate.mlir b/mlir/test/Target/LLVMIR/omptarget-groupprivate.mlir
new file mode 100644
index 0000000000000..f064996427d96
--- /dev/null
+++ b/mlir/test/Target/LLVMIR/omptarget-groupprivate.mlir
@@ -0,0 +1,41 @@
+// RUN: mlir-translate -mlir-to-llvmir %s | FileCheck %s
+
+module attributes {omp.is_target_device = true, llvm.target_triple = "amdgcn-amd-amdhsa",
+ dlti.dl_spec = #dlti.dl_spec<#dlti.dl_entry<"dlti.alloca_memory_space", 5 : ui32>>} {
+ llvm.func @_QQmain() attributes {fir.bindc_name = "main"} {
+
+ %ga = llvm.mlir.addressof @global_a : !llvm.ptr
+ %map_a = omp.map.info var_ptr(%ga : !llvm.ptr, i32) map_clauses(tofrom) capture(ByCopy) -> !llvm.ptr {name = "i"}
+ omp.target map_entries(%map_a -> %arg1 : !llvm.ptr) {
+ %loaded = llvm.load %arg1 : !llvm.ptr -> i32
+
+ %any_gp = omp.groupprivate @global_any device_type(any) : !llvm.ptr
+ llvm.store %loaded, %any_gp : i32, !llvm.ptr
+
+ %host_gp = omp.groupprivate @global_host device_type(host) : !llvm.ptr
+ llvm.store %loaded, %host_gp : i32, !llvm.ptr
+
+ %nohost_gp = omp.groupprivate @global_nohost device_type(nohost) : !llvm.ptr
+ llvm.store %loaded, %nohost_gp : i32, !llvm.ptr
+
+ omp.terminator
+ }
+ llvm.return
+ }
+ llvm.mlir.global internal @global_a() : i32
+ llvm.mlir.global internal @global_any() : i32
+ llvm.mlir.global internal @global_host() : i32
+ llvm.mlir.global internal @global_nohost() : i32
+}
+
+// CHECK-DAG: @global_a = internal global i32 undef
+// CHECK-DAG: @global_any = internal global i32 undef
+// CHECK-DAG: @global_host = internal global i32 undef
+// CHECK-DAG: @global_nohost = internal global i32 undef
+// CHECK-DAG: @[[SHARED_ANY:global_any.*]] = internal addrspace(3) global i32 poison
+// CHECK-DAG: @[[SHARED_NOHOST:global_nohost.*]] = internal addrspace(3) global i32 poison
+// CHECK: define {{.*}} amdgpu_kernel void @__omp_offloading_{{.*}}_{{.*}}__QQmain_{{.*}}(ptr %{{.*}}, ptr %{{.*}}) #{{[0-9]+}} {
+// CHECK: %[[LOAD:.*]] = load i32, ptr %{{.*}}, align 4
+// CHECK-NEXT : store i32 %[[LOAD]], ptr addrspace(3) @[[SHARED_ANY]], align 4
+// CHECK-NEXT : store i32 %[[LOAD]], ptr @global_host, align 4
+// CHECK-NEXT : store i32 %[[LOAD]], ptr addrspace(3) @[[SHARED_NOHOST]], align 4
diff --git a/mlir/test/Target/LLVMIR/openmp-llvm.mlir b/mlir/test/Target/LLVMIR/openmp-llvm.mlir
index 64e0b188a0639..f002a64a593a0 100644
--- a/mlir/test/Target/LLVMIR/openmp-llvm.mlir
+++ b/mlir/test/Target/LLVMIR/openmp-llvm.mlir
@@ -3730,3 +3730,66 @@ llvm.func @task_affinity_plain(%arr: !llvm.ptr {llvm.nocapture}) {
// CHECK: [[FLAGGEP:%.*]] = getelementptr inbounds nuw { i64, i64, i32 }, ptr [[ENTRY]], i32 0, i32 2
// CHECK: store i32 0, ptr [[FLAGGEP]]
// CHECK: call i32 @__kmpc_omp_reg_task_with_affinity{{.*}}i32 1, ptr [[AFFLIST]]
+
+// -----
+
+module attributes {omp.is_target_device = true, llvm.target_triple = "nvptx64-nvidia-cuda"} {
+llvm.mlir.global internal @any() : i32
+llvm.mlir.global internal @host() : i32
+llvm.mlir.global internal @nohost() : i32
+llvm.func @omp_groupprivate_device() attributes {
+ omp.declare_target = #omp.declaretarget<device_type = (any), capture_clause = (to)>} {
+ %0 = llvm.mlir.constant(1 : i32) : i32
+ %2 = omp.groupprivate @any device_type(any) : !llvm.ptr
+ llvm.store %0, %2 : i32, !llvm.ptr
+
+ %4 = omp.groupprivate @host device_type(host) : !llvm.ptr
+ llvm.store %0, %4 : i32, !llvm.ptr
+
+ %6 = omp.groupprivate @nohost device_type(nohost) : !llvm.ptr
+ llvm.store %0, %6 : i32, !llvm.ptr
+ llvm.return
+}
+}
+
+// CHECK-DAG: @any = internal global i32 undef
+// CHECK-DAG: @host = internal global i32 undef
+// CHECK-DAG: @nohost = internal global i32 undef
+// CHECK-DAG: @[[SHARED_ANY:any.*]] = internal addrspace(3) global i32 poison
+// CHECK-DAG: @[[SHARED_NOHOST:nohost.*]] = internal addrspace(3) global i32 poison
+// CHECK: define void @omp_groupprivate_device()
+// CHECK: store i32 1, ptr addrspace(3) @[[SHARED_ANY]], align 4
+// CHECK: store i32 1, ptr @host, align 4
+// CHECK: store i32 1, ptr addrspace(3) @[[SHARED_NOHOST]], align 4
+// CHECK: ret void
+
+// -----
+
+module attributes {omp.is_target_device = false} {
+llvm.mlir.global internal @any1() : i32
+llvm.mlir.global internal @host1() : i32
+llvm.mlir.global internal @nohost1() : i32
+llvm.func @omp_groupprivate_host() {
+ %0 = llvm.mlir.constant(1 : i32) : i32
+ %2 = omp.groupprivate @any1 device_type(any) : !llvm.ptr
+ llvm.store %0, %2 : i32, !llvm.ptr
+
+ %4 = omp.groupprivate @host1 device_type(host) : !llvm.ptr
+ llvm.store %0, %4 : i32, !llvm.ptr
+
+ %6 = omp.groupprivate @nohost1 device_type(nohost) : !llvm.ptr
+ llvm.store %0, %6 : i32, !llvm.ptr
+ llvm.return
+}
+}
+
+// CHECK-DAG: @any1 = internal global i32 undef
+// CHECK-DAG: @host1 = internal global i32 undef
+// CHECK-DAG: @nohost1 = internal global i32 undef
+// CHECK-LABEL: define void @omp_groupprivate_host()
+// CHECK: store i32 1, ptr @any1, align 4
+// CHECK: store i32 1, ptr @host1, align 4
+// CHECK: store i32 1, ptr @nohost1, align 4
+// CHECK: ret void
+
+// -----
More information about the Mlir-commits
mailing list