[Mlir-commits] [mlir] [mlir][arith] Add comparison regression tests (PR #96974)

[Andrzej Warzyński]

================
@@ -0,0 +1,123 @@
+// RUN: mlir-opt %s --convert-scf-to-cf --convert-cf-to-llvm --convert-vector-to-llvm \
+// RUN:             --convert-func-to-llvm --convert-arith-to-llvm | \
+// RUN:   mlir-cpu-runner -e entry -entry-point-result=void \
+// RUN:                   --shared-libs=%mlir_c_runner_utils | \
+// RUN:   FileCheck %s --match-full-lines
+
+func.func @cmpi_slt_i1(%v1 : i1, %v2 : i1) {
+  vector.print str "@cmpi_slt_i1\n"
+  %res = arith.cmpi slt, %v1, %v2 : i1
+  vector.print %res : i1
+  return
+}
+
+func.func @cmpi_sle_i1(%v1 : i1, %v2 : i1) {
+  vector.print str "@cmpi_sle_i1\n"
+  %res = arith.cmpi sle, %v1, %v2 : i1
+  vector.print %res : i1
+  return
+}
+
+func.func @cmpi_sgt_i1(%v1 : i1, %v2 : i1) {
+  vector.print str "@cmpi_sgt_i1\n"
+  %res = arith.cmpi sgt, %v1, %v2 : i1
+  vector.print %res : i1
+  return
+}
+
+func.func @cmpi_sge_i1(%v1 : i1, %v2 : i1) {
+  vector.print str "@cmpi_sge_i1\n"
+  %res = arith.cmpi sge, %v1, %v2 : i1
+  vector.print %res : i1
+  return
+}
+
+func.func @cmpi_signed() {
+  // ------------------------------------------------
+  // Test i1
+  // ------------------------------------------------
+  %false_i1 = arith.constant 0 : i1
+  %true_i1 = arith.constant 1 : i1
+  %true_i1_n1 = arith.constant -1 : i1
+
+  // sge 0 -1, sge 0 1, should be true
+  // since the bitvector `1` is interpreted as the int value -1 in signed comparisons
+  // sge 0 -1 == sge 0 1 == true (1)
+
+  // CHECK-LABEL: @cmpi_sge_i1
+  // CHECK-NEXT:  1
+  func.call @cmpi_sge_i1(%false_i1, %true_i1_n1) : (i1, i1) -> ()
+
+  // CHECK-LABEL: @cmpi_sge_i1
+  // CHECK-NEXT:  1
+  func.call @cmpi_sge_i1(%false_i1, %true_i1) : (i1, i1) -> ()
+
+  %false = arith.constant false
+  %true = arith.constant true
+
+  // signed comparisons on i1s
+  // slt 0 1 = false, sle 0 1 = false, sgt 0 1 = true, sge 0 1 = true
+
+  // CHECK-LABEL: @cmpi_slt_i1
+  // CHECK-NEXT:  0
+  func.call @cmpi_slt_i1(%false, %true) : (i1, i1) -> ()
+
+  // CHECK-LABEL: @cmpi_sle_i1
+  // CHECK-NEXT:  0
+  func.call @cmpi_sle_i1(%false, %true) : (i1, i1) -> ()
+
+  // CHECK-LABEL: @cmpi_sgt_i1
+  // CHECK-NEXT:  1
+  func.call @cmpi_sgt_i1(%false, %true) : (i1, i1) -> ()
+
+  // CHECK-LABEL: @cmpi_sge_i1
+  // CHECK-NEXT:  1
+  func.call @cmpi_sge_i1(%false, %true) : (i1, i1) -> ()
+
+  // check that addui_extended overflow bit is treated as -1 in comparison operations
+  //  in the case of an overflow
+  // addui_extended -1 -1 = (..., overflow_bit) 
----------------
banach-space wrote:

I still think that this file should be limited to `arith.cmp` (i.e. comparison) operations. As in, there should be no `arith.addui_extended`. 

IMO, this test is mixing two orthogonal questions:
1. Does `%sum, %overflow = arith.addui_extended %n1_i64, %n1_i64 : i64, i1` return `1` as the overflow bit? It should and the right place to verify that would be https://github.com/llvm/llvm-project/pull/96973.
2. Does `func.call @cmpi_sge_i1(%overflow, %false) : (i1, i1) -> ()` return 0? It does. 

Note that 2. can also be verified by writing: `func.call @cmpi_sge_i1(%true, %false) : (i1, i1) -> ()`. IMHO that would be much better/cleaner/intuitive and would nicely complement your test on L75.



https://github.com/llvm/llvm-project/pull/96974