[Mlir-commits] [mlir] 25243d7 - [mlir][OpenMP] Add aligned clause definition to simd construct
Dominik Adamski
llvmlistbot at llvm.org
Tue Nov 1 09:10:17 PDT 2022
Author: Dominik Adamski
Date: 2022-11-01T11:07:53-05:00
New Revision: 25243d717dc944bca1b6441686815be84ec8bbf0
URL: https://github.com/llvm/llvm-project/commit/25243d717dc944bca1b6441686815be84ec8bbf0
DIFF: https://github.com/llvm/llvm-project/commit/25243d717dc944bca1b6441686815be84ec8bbf0.diff
LOG: [mlir][OpenMP] Add aligned clause definition to simd construct
simd aligned construct is represented as pair of variable which needs
to be aligned and corresponding alignment value.
Added parser, printer and verifier of aligned clause. MLIR tests were
updated to test correctness of MLIR definition of aligned clause.
Differential Revision: https://reviews.llvm.org/D135865
Reviewed By: kiranchandramohan
Added:
Modified:
flang/lib/Lower/OpenMP.cpp
mlir/include/mlir/Dialect/OpenMP/OpenMPOps.td
mlir/lib/Dialect/OpenMP/IR/OpenMPDialect.cpp
mlir/test/Dialect/OpenMP/invalid.mlir
mlir/test/Dialect/OpenMP/ops.mlir
mlir/test/Target/LLVMIR/openmp-llvm.mlir
Removed:
################################################################################
diff --git a/flang/lib/Lower/OpenMP.cpp b/flang/lib/Lower/OpenMP.cpp
index adada64e3cf49..4d47b95e00eed 100644
--- a/flang/lib/Lower/OpenMP.cpp
+++ b/flang/lib/Lower/OpenMP.cpp
@@ -1054,7 +1054,7 @@ static void genOMP(Fortran::lower::AbstractConverter &converter,
fir::FirOpBuilder &firOpBuilder = converter.getFirOpBuilder();
mlir::Location currentLocation = converter.getCurrentLocation();
llvm::SmallVector<mlir::Value> lowerBound, upperBound, step, linearVars,
- linearStepVars, reductionVars;
+ linearStepVars, reductionVars, alignedVars;
mlir::Value scheduleChunkClauseOperand, ifClauseOperand;
mlir::Attribute scheduleClauseOperand, noWaitClauseOperand,
orderedClauseOperand, orderClauseOperand;
@@ -1213,8 +1213,8 @@ static void genOMP(Fortran::lower::AbstractConverter &converter,
if (llvm::omp::OMPD_simd == ompDirective) {
TypeRange resultType;
auto SimdLoopOp = firOpBuilder.create<mlir::omp::SimdLoopOp>(
- currentLocation, resultType, lowerBound, upperBound, step,
- ifClauseOperand, simdlenClauseOperand, safelenClauseOperand,
+ currentLocation, resultType, lowerBound, upperBound, step, alignedVars,
+ nullptr, ifClauseOperand, simdlenClauseOperand, safelenClauseOperand,
/*inclusive=*/firOpBuilder.getUnitAttr());
createBodyOfOp<omp::SimdLoopOp>(SimdLoopOp, converter, currentLocation,
eval, &loopOpClauseList, iv);
diff --git a/mlir/include/mlir/Dialect/OpenMP/OpenMPOps.td b/mlir/include/mlir/Dialect/OpenMP/OpenMPOps.td
index e6fde2d786469..999e2bec5551a 100644
--- a/mlir/include/mlir/Dialect/OpenMP/OpenMPOps.td
+++ b/mlir/include/mlir/Dialect/OpenMP/OpenMPOps.td
@@ -385,6 +385,10 @@ def SimdLoopOp : OpenMP_Op<"simdloop", [AttrSizedOperandSegments,
Collapsed loops are represented by the simd-loop having a list of indices,
bounds and steps where the size of the list is equal to the collapse value.
+ The `alignment_values` attribute additionally specifies alignment of each
+ corresponding aligned operand. Note that `$aligned_vars` and
+ `alignment_values` should contain the same number of elements.
+
When an if clause is present and evaluates to false, the preferred number of
iterations to be executed concurrently is one, regardless of whether
a simdlen clause is speciļ¬ed.
@@ -408,6 +412,8 @@ def SimdLoopOp : OpenMP_Op<"simdloop", [AttrSizedOperandSegments,
let arguments = (ins Variadic<IntLikeType>:$lowerBound,
Variadic<IntLikeType>:$upperBound,
Variadic<IntLikeType>:$step,
+ Variadic<OpenMP_PointerLikeType>:$aligned_vars,
+ OptionalAttr<I64ArrayAttr>:$alignment_values,
Optional<I1>:$if_expr,
ConfinedAttr<OptionalAttr<I64Attr>, [IntPositive]>:$simdlen,
ConfinedAttr<OptionalAttr<I64Attr>, [IntPositive]>:$safelen,
@@ -416,7 +422,10 @@ def SimdLoopOp : OpenMP_Op<"simdloop", [AttrSizedOperandSegments,
let regions = (region AnyRegion:$region);
let assemblyFormat = [{
- oilist(`if` `(` $if_expr `)`
+ oilist(`aligned` `(`
+ custom<AlignedClause>($aligned_vars, type($aligned_vars),
+ $alignment_values) `)`
+ |`if` `(` $if_expr `)`
|`simdlen` `(` $simdlen `)`
|`safelen` `(` $safelen `)`
) `for` custom<LoopControl>($region, $lowerBound, $upperBound, $step,
diff --git a/mlir/lib/Dialect/OpenMP/IR/OpenMPDialect.cpp b/mlir/lib/Dialect/OpenMP/IR/OpenMPDialect.cpp
index 78a1cfd3a853d..ba762339168ee 100644
--- a/mlir/lib/Dialect/OpenMP/IR/OpenMPDialect.cpp
+++ b/mlir/lib/Dialect/OpenMP/IR/OpenMPDialect.cpp
@@ -170,6 +170,81 @@ static void printLinearClause(OpAsmPrinter &p, Operation *op,
}
}
+//===----------------------------------------------------------------------===//
+// Parser, verifier and printer for Aligned Clause
+//===----------------------------------------------------------------------===//
+static LogicalResult verifyAlignedClause(Operation *op,
+ Optional<ArrayAttr> alignmentValues,
+ OperandRange alignedVariables) {
+ // Check if number of alignment values equals to number of aligned variables
+ if (!alignedVariables.empty()) {
+ if (!alignmentValues || alignmentValues->size() != alignedVariables.size())
+ return op->emitOpError()
+ << "expected as many alignment values as aligned variables";
+ } else {
+ if (alignmentValues)
+ return op->emitOpError() << "unexpected alignment values attribute";
+ return success();
+ }
+
+ // Check if each var is aligned only once - OpenMP 4.5 -> 2.8.1 section
+ DenseSet<Value> alignedItems;
+ for (auto it : alignedVariables)
+ if (!alignedItems.insert(it).second)
+ return op->emitOpError() << "aligned variable used more than once";
+
+ if (!alignmentValues)
+ return success();
+
+ // Check if all alignment values are positive - OpenMP 4.5 -> 2.8.1 section
+ for (unsigned i = 0; i < (*alignmentValues).size(); ++i) {
+ if (auto intAttr = (*alignmentValues)[i].dyn_cast<IntegerAttr>()) {
+ if (intAttr.getValue().sle(0))
+ return op->emitOpError() << "alignment should be greater than 0";
+ } else {
+ return op->emitOpError() << "expected integer alignment";
+ }
+ }
+
+ return success();
+}
+
+/// aligned ::= `aligned` `(` aligned-list `)`
+/// aligned-list := aligned-val | aligned-val aligned-list
+/// aligned-val := ssa-id-and-type `->` alignment
+static ParseResult parseAlignedClause(
+ OpAsmParser &parser,
+ SmallVectorImpl<OpAsmParser::UnresolvedOperand> &alignedItems,
+ SmallVectorImpl<Type> &types, ArrayAttr &alignmentValues) {
+ SmallVector<Attribute> alignmentVec;
+ if (failed(parser.parseCommaSeparatedList([&]() {
+ if (parser.parseOperand(alignedItems.emplace_back()) ||
+ parser.parseColonType(types.emplace_back()) ||
+ parser.parseArrow() ||
+ parser.parseAttribute(alignmentVec.emplace_back())) {
+ return failure();
+ }
+ return success();
+ })))
+ return failure();
+ SmallVector<Attribute> alignments(alignmentVec.begin(), alignmentVec.end());
+ alignmentValues = ArrayAttr::get(parser.getContext(), alignments);
+ return success();
+}
+
+/// Print Aligned Clause
+static void printAlignedClause(OpAsmPrinter &p, Operation *op,
+ ValueRange alignedVars,
+ TypeRange alignedVarTypes,
+ Optional<ArrayAttr> alignmentValues) {
+ for (unsigned i = 0; i < alignedVars.size(); ++i) {
+ if (i != 0)
+ p << ", ";
+ p << alignedVars[i] << " : " << alignedVars[i].getType();
+ p << " -> " << (*alignmentValues)[i];
+ }
+}
+
//===----------------------------------------------------------------------===//
// Parser, printer and verifier for Schedule Clause
//===----------------------------------------------------------------------===//
@@ -583,8 +658,8 @@ LogicalResult SimdLoopOp::verify() {
<< "simdlen clause and safelen clause are both present, but the "
"simdlen value is not less than or equal to safelen value";
}
-
- return success();
+ return verifyAlignedClause(*this, this->getAlignmentValues(),
+ this->getAlignedVars());
}
//===----------------------------------------------------------------------===//
diff --git a/mlir/test/Dialect/OpenMP/invalid.mlir b/mlir/test/Dialect/OpenMP/invalid.mlir
index ef0fc9d0057a8..e0097846db546 100644
--- a/mlir/test/Dialect/OpenMP/invalid.mlir
+++ b/mlir/test/Dialect/OpenMP/invalid.mlir
@@ -197,7 +197,7 @@ func.func @omp_simdloop(%lb : index, %ub : index, %step : i32) -> () {
"omp.simdloop" (%lb, %ub, %step) ({
^bb0(%iv: index):
omp.yield
- }) {operand_segment_sizes = array<i32: 1,1,1,0>} :
+ }) {operand_segment_sizes = array<i32: 1,1,1,0,0>} :
(index, index, i32) -> ()
return
@@ -205,6 +205,84 @@ func.func @omp_simdloop(%lb : index, %ub : index, %step : i32) -> () {
// -----
+func.func @omp_simdloop_pretty_aligned(%lb : index, %ub : index, %step : index,
+ %data_var : memref<i32>) -> () {
+ // expected-error @below {{expected '->'}}
+ omp.simdloop aligned(%data_var : memref<i32>)
+ for (%iv) : index = (%lb) to (%ub) step (%step) {
+ omp.yield
+ }
+ return
+}
+
+// -----
+
+func.func @omp_simdloop_aligned_mismatch(%arg0 : index, %arg1 : index,
+ %arg2 : index, %arg3 : memref<i32>,
+ %arg4 : memref<i32>) -> () {
+ // expected-error @below {{op expected as many alignment values as aligned variables}}
+ "omp.simdloop"(%arg0, %arg1, %arg2, %arg3, %arg4) ({
+ ^bb0(%arg5: index):
+ "omp.yield"() : () -> ()
+ }) {alignment_values = [128],
+ operand_segment_sizes = array<i32: 1, 1, 1, 2, 0>} : (index, index, index, memref<i32>, memref<i32>) -> ()
+ return
+}
+
+// -----
+
+func.func @omp_simdloop_aligned_negative(%arg0 : index, %arg1 : index,
+ %arg2 : index, %arg3 : memref<i32>,
+ %arg4 : memref<i32>) -> () {
+ // expected-error @below {{op alignment should be greater than 0}}
+ "omp.simdloop"(%arg0, %arg1, %arg2, %arg3, %arg4) ({
+ ^bb0(%arg5: index):
+ "omp.yield"() : () -> ()
+ }) {alignment_values = [-1, 128], operand_segment_sizes = array<i32: 1, 1, 1,2, 0>} : (index, index, index, memref<i32>, memref<i32>) -> ()
+ return
+}
+
+// -----
+
+func.func @omp_simdloop_unexpected_alignment(%arg0 : index, %arg1 : index,
+ %arg2 : index, %arg3 : memref<i32>,
+ %arg4 : memref<i32>) -> () {
+ // expected-error @below {{unexpected alignment values attribute}}
+ "omp.simdloop"(%arg0, %arg1, %arg2) ({
+ ^bb0(%arg5: index):
+ "omp.yield"() : () -> ()
+ }) {alignment_values = [1, 128], operand_segment_sizes = array<i32: 1, 1, 1, 0, 0>} : (index, index, index) -> ()
+ return
+}
+
+// -----
+
+func.func @omp_simdloop_aligned_float(%arg0 : index, %arg1 : index,
+ %arg2 : index, %arg3 : memref<i32>,
+ %arg4 : memref<i32>) -> () {
+ // expected-error @below {{failed to satisfy constraint: 64-bit integer array attribute}}
+ "omp.simdloop"(%arg0, %arg1, %arg2, %arg3, %arg4) ({
+ ^bb0(%arg5: index):
+ "omp.yield"() : () -> ()
+ }) {alignment_values = [1.5, 128], operand_segment_sizes = array<i32: 1, 1, 1,2, 0>} : (index, index, index, memref<i32>, memref<i32>) -> ()
+ return
+}
+
+// -----
+
+func.func @omp_simdloop_aligned_the_same_var(%arg0 : index, %arg1 : index,
+ %arg2 : index, %arg3 : memref<i32>,
+ %arg4 : memref<i32>) -> () {
+ // expected-error @below {{aligned variable used more than once}}
+ "omp.simdloop"(%arg0, %arg1, %arg2, %arg3, %arg3) ({
+ ^bb0(%arg5: index):
+ "omp.yield"() : () -> ()
+ }) {alignment_values = [1, 128], operand_segment_sizes = array<i32: 1, 1, 1,2, 0>} : (index, index, index, memref<i32>, memref<i32>) -> ()
+ return
+}
+
+// -----
+
func.func @omp_simdloop_pretty_simdlen(%lb : index, %ub : index, %step : index) -> () {
// expected-error @below {{op attribute 'simdlen' failed to satisfy constraint: 64-bit signless integer attribute whose value is positive}}
omp.simdloop simdlen(0) for (%iv): index = (%lb) to (%ub) step (%step) {
diff --git a/mlir/test/Dialect/OpenMP/ops.mlir b/mlir/test/Dialect/OpenMP/ops.mlir
index 74dc12e86175d..fad78b2b0ca96 100644
--- a/mlir/test/Dialect/OpenMP/ops.mlir
+++ b/mlir/test/Dialect/OpenMP/ops.mlir
@@ -333,12 +333,39 @@ func.func @omp_simdloop(%lb : index, %ub : index, %step : index) -> () {
"omp.simdloop" (%lb, %ub, %step) ({
^bb0(%iv: index):
omp.yield
- }) {operand_segment_sizes = array<i32: 1,1,1,0>} :
+ }) {operand_segment_sizes = array<i32: 1,1,1,0,0>} :
(index, index, index) -> ()
return
}
+// CHECK-LABEL: omp_simdloop_aligned_list
+func.func @omp_simdloop_aligned_list(%arg0 : index, %arg1 : index, %arg2 : index,
+ %arg3 : memref<i32>, %arg4 : memref<i32>) -> () {
+ // CHECK: omp.simdloop aligned(%{{.*}} : memref<i32> -> 32 : i64,
+ // CHECK-SAME: %{{.*}} : memref<i32> -> 128 : i64)
+ // CHECK-SAME: for (%{{.*}}) : index = (%{{.*}}) to (%{{.*}}) step (%{{.*}}) {
+ "omp.simdloop"(%arg0, %arg1, %arg2, %arg3, %arg4) ({
+ ^bb0(%arg5: index):
+ "omp.yield"() : () -> ()
+ }) {alignment_values = [32, 128],
+ operand_segment_sizes = array<i32: 1, 1, 1,2, 0>} : (index, index, index, memref<i32>, memref<i32>) -> ()
+ return
+}
+
+// CHECK-LABEL: omp_simdloop_aligned_single
+func.func @omp_simdloop_aligned_single(%arg0 : index, %arg1 : index, %arg2 : index,
+ %arg3 : memref<i32>, %arg4 : memref<i32>) -> () {
+ // CHECK: omp.simdloop aligned(%{{.*}} : memref<i32> -> 32 : i64)
+ // CHECK-SAME: for (%{{.*}}) : index = (%{{.*}}) to (%{{.*}}) step (%{{.*}}) {
+ "omp.simdloop"(%arg0, %arg1, %arg2, %arg3) ({
+ ^bb0(%arg5: index):
+ "omp.yield"() : () -> ()
+ }) {alignment_values = [32],
+ operand_segment_sizes = array<i32: 1, 1, 1,1, 0>} : (index, index, index, memref<i32>) -> ()
+ return
+}
+
// CHECK-LABEL: omp_simdloop_pretty
func.func @omp_simdloop_pretty(%lb : index, %ub : index, %step : index) -> () {
// CHECK: omp.simdloop for (%{{.*}}) : index = (%{{.*}}) to (%{{.*}}) step (%{{.*}})
@@ -348,6 +375,20 @@ func.func @omp_simdloop_pretty(%lb : index, %ub : index, %step : index) -> () {
return
}
+// CHECK-LABEL: func.func @omp_simdloop_pretty_aligned(
+func.func @omp_simdloop_pretty_aligned(%lb : index, %ub : index, %step : index,
+ %data_var : memref<i32>,
+ %data_var1 : memref<i32>) -> () {
+ // CHECK: omp.simdloop aligned(%{{.*}} : memref<i32> -> 32 : i64,
+ // CHECK-SAME: %{{.*}} : memref<i32> -> 128 : i64)
+ // CHECK-SAME: for (%{{.*}}) : index = (%{{.*}}) to (%{{.*}}) step (%{{.*}}) {
+ omp.simdloop aligned(%data_var : memref<i32> -> 32, %data_var1 : memref<i32> -> 128)
+ for (%iv) : index = (%lb) to (%ub) step (%step) {
+ omp.yield
+ }
+ return
+}
+
// CHECK-LABEL: omp_simdloop_pretty_if
func.func @omp_simdloop_pretty_if(%lb : index, %ub : index, %step : index, %if_cond : i1) -> () {
// CHECK: omp.simdloop if(%{{.*}}) for (%{{.*}}) : index = (%{{.*}}) to (%{{.*}}) step (%{{.*}})
diff --git a/mlir/test/Target/LLVMIR/openmp-llvm.mlir b/mlir/test/Target/LLVMIR/openmp-llvm.mlir
index 82a9c1fa53609..aa986debb49c9 100644
--- a/mlir/test/Target/LLVMIR/openmp-llvm.mlir
+++ b/mlir/test/Target/LLVMIR/openmp-llvm.mlir
@@ -694,7 +694,7 @@ llvm.func @simdloop_simple(%lb : i64, %ub : i64, %step : i64, %arg0: !llvm.ptr<f
%4 = llvm.getelementptr %arg0[%iv] : (!llvm.ptr<f32>, i64) -> !llvm.ptr<f32>
llvm.store %3, %4 : !llvm.ptr<f32>
omp.yield
- }) {operand_segment_sizes = array<i32: 1,1,1,0>} :
+ }) {operand_segment_sizes = array<i32: 1,1,1,0,0>} :
(i64, i64, i64) -> ()
llvm.return
More information about the Mlir-commits
mailing list