[llvm] [LAA] ZExt size from deref bundles to widest type. (PR #217939)
Florian Hahn via llvm-commits
llvm-commits at lists.llvm.org
Sat Aug 22 05:51:41 PDT 2026
https://github.com/fhahn updated https://github.com/llvm/llvm-project/pull/217939
>From c1024b6cf9ebefa8498132f2b269a020f38110da Mon Sep 17 00:00:00 2001
From: Florian Hahn <flo at fhahn.com>
Date: Fri, 21 Aug 2026 09:19:48 +0100
Subject: [PATCH] [LAA] ZExt size from deref bundles to widest type.
The size in a dereferenceable bundle may have a different bitwidth than
the access size. Both are interpreted as unsigned values. Update
WidestTy to account for possibility of the type for the bundle being
narrower.
Fixes a crash similar to
https://github.com/llvm/llvm-project/pull/217770.
---
llvm/lib/Analysis/LoopAccessAnalysis.cpp | 1 +
...able-info-from-assumption-constant-size.ll | 106 ++++++++++++++++++
2 files changed, 107 insertions(+)
diff --git a/llvm/lib/Analysis/LoopAccessAnalysis.cpp b/llvm/lib/Analysis/LoopAccessAnalysis.cpp
index 4650d630fd0ba..9b407b1ca4729 100644
--- a/llvm/lib/Analysis/LoopAccessAnalysis.cpp
+++ b/llvm/lib/Analysis/LoopAccessAnalysis.cpp
@@ -265,6 +265,7 @@ static bool evaluatePtrAddRecAtMaxBTCWillNotWrap(
if (!IsKnownNonNegative && !SE.isKnownNegative(Step))
return false;
+ WiderTy = SE.getWiderType(WiderTy, DerefBytesSCEV->getType());
Step = SE.getNoopOrSignExtend(Step, WiderTy);
MaxBTC = SE.getNoopOrZeroExtend(MaxBTC, WiderTy);
diff --git a/llvm/test/Transforms/LoopVectorize/dereferenceable-info-from-assumption-constant-size.ll b/llvm/test/Transforms/LoopVectorize/dereferenceable-info-from-assumption-constant-size.ll
index 426e2bd7cde9d..0c9317244c79a 100644
--- a/llvm/test/Transforms/LoopVectorize/dereferenceable-info-from-assumption-constant-size.ll
+++ b/llvm/test/Transforms/LoopVectorize/dereferenceable-info-from-assumption-constant-size.ll
@@ -1,6 +1,7 @@
; NOTE: Assertions have been autogenerated by utils/update_test_checks.py UTC_ARGS: --check-globals none --filter-out-after "scalar.ph:" --version 6
; RUN: opt -p loop-vectorize -force-vector-width=2 -force-target-supports-masked-memory-ops -S %s | FileCheck %s
+target datalayout = "p1:32:32"
define void @deref_assumption_in_header_constant_trip_count(ptr noalias noundef %a, ptr noalias %b, ptr noalias %c) nofree nosync{
; CHECK-LABEL: define void @deref_assumption_in_header_constant_trip_count(
@@ -1625,3 +1626,108 @@ loop.latch:
exit:
ret void
}
+
+define i32 @deref_assumption_size_wider_than_index_type(ptr addrspace(1) noalias %p1, ptr addrspace(1) noalias %p2) nofree nosync {
+; CHECK-LABEL: define i32 @deref_assumption_size_wider_than_index_type(
+; CHECK-SAME: ptr addrspace(1) noalias [[P1:%.*]], ptr addrspace(1) noalias [[P2:%.*]]) #[[ATTR0]] {
+; CHECK-NEXT: [[ENTRY:.*:]]
+; CHECK-NEXT: call void @llvm.assume(i1 true) [ "dereferenceable"(ptr addrspace(1) [[P1]], i64 1024) ]
+; CHECK-NEXT: call void @llvm.assume(i1 true) [ "dereferenceable"(ptr addrspace(1) [[P2]], i64 1024) ]
+; CHECK-NEXT: br label %[[VECTOR_PH:.*]]
+; CHECK: [[VECTOR_PH]]:
+; CHECK-NEXT: br label %[[VECTOR_BODY:.*]]
+; CHECK: [[VECTOR_BODY]]:
+; CHECK-NEXT: [[INDEX1:%.*]] = phi i32 [ 0, %[[VECTOR_PH]] ], [ [[INDEX_NEXT3:%.*]], %[[VECTOR_BODY_INTERIM:.*]] ]
+; CHECK-NEXT: [[TMP0:%.*]] = getelementptr inbounds i8, ptr addrspace(1) [[P1]], i32 [[INDEX1]]
+; CHECK-NEXT: [[WIDE_LOAD:%.*]] = load <2 x i8>, ptr addrspace(1) [[TMP0]], align 1
+; CHECK-NEXT: [[TMP1:%.*]] = getelementptr inbounds i8, ptr addrspace(1) [[P2]], i32 [[INDEX1]]
+; CHECK-NEXT: [[WIDE_LOAD1:%.*]] = load <2 x i8>, ptr addrspace(1) [[TMP1]], align 1
+; CHECK-NEXT: [[TMP2:%.*]] = icmp ne <2 x i8> [[WIDE_LOAD]], [[WIDE_LOAD1]]
+; CHECK-NEXT: [[TMP3:%.*]] = freeze <2 x i1> [[TMP2]]
+; CHECK-NEXT: [[TMP4:%.*]] = call i1 @llvm.vector.reduce.or.v2i1(<2 x i1> [[TMP3]])
+; CHECK-NEXT: [[INDEX_NEXT3]] = add nuw i32 [[INDEX1]], 2
+; CHECK-NEXT: [[TMP5:%.*]] = icmp eq i32 [[INDEX_NEXT3]], 1024
+; CHECK-NEXT: br i1 [[TMP4]], label %[[VECTOR_EARLY_EXIT:.*]], label %[[VECTOR_BODY_INTERIM]]
+; CHECK: [[VECTOR_BODY_INTERIM]]:
+; CHECK-NEXT: br i1 [[TMP5]], label %[[MIDDLE_BLOCK:.*]], label %[[VECTOR_BODY]], !llvm.loop [[LOOP32:![0-9]+]]
+; CHECK: [[MIDDLE_BLOCK]]:
+; CHECK-NEXT: br label %[[LOOP_END:.*]]
+; CHECK: [[VECTOR_EARLY_EXIT]]:
+; CHECK-NEXT: [[TMP6:%.*]] = call i64 @llvm.experimental.cttz.elts.i64.v2i1(<2 x i1> [[TMP2]], i1 false)
+; CHECK-NEXT: [[TMP7:%.*]] = trunc i64 [[TMP6]] to i32
+; CHECK-NEXT: [[TMP8:%.*]] = add i32 [[INDEX1]], [[TMP7]]
+; CHECK-NEXT: br label %[[LOOP_END]]
+; CHECK: [[LOOP_END]]:
+; CHECK-NEXT: [[RETVAL:%.*]] = phi i32 [ [[TMP8]], %[[VECTOR_EARLY_EXIT]] ], [ -1, %[[MIDDLE_BLOCK]] ]
+; CHECK-NEXT: ret i32 [[RETVAL]]
+;
+entry:
+ call void @llvm.assume(i1 true) [ "dereferenceable"(ptr addrspace(1) %p1, i64 1024) ]
+ call void @llvm.assume(i1 true) [ "dereferenceable"(ptr addrspace(1) %p2, i64 1024) ]
+ br label %loop.header
+
+loop.header:
+ %iv = phi i32 [ 0, %entry ], [ %iv.next, %loop.latch ]
+ %gep.p1 = getelementptr inbounds i8, ptr addrspace(1) %p1, i32 %iv
+ %ld1 = load i8, ptr addrspace(1) %gep.p1, align 1
+ %gep.p2 = getelementptr inbounds i8, ptr addrspace(1) %p2, i32 %iv
+ %ld2 = load i8, ptr addrspace(1) %gep.p2, align 1
+ %c.0 = icmp eq i8 %ld1, %ld2
+ br i1 %c.0, label %loop.latch, label %loop.end
+
+loop.latch:
+ %iv.next = add i32 %iv, 1
+ %exitcond = icmp ne i32 %iv.next, 1024
+ br i1 %exitcond, label %loop.header, label %loop.end
+
+loop.end:
+ %retval = phi i32 [ %iv, %loop.header ], [ -1, %loop.latch ]
+ ret i32 %retval
+}
+
+define i32 @deref_assumption_size_wider_than_index_type_too_small(ptr addrspace(1) noalias %p1, ptr addrspace(1) noalias %p2) nofree nosync {
+; CHECK-LABEL: define i32 @deref_assumption_size_wider_than_index_type_too_small(
+; CHECK-SAME: ptr addrspace(1) noalias [[P1:%.*]], ptr addrspace(1) noalias [[P2:%.*]]) #[[ATTR0]] {
+; CHECK-NEXT: [[ENTRY:.*]]:
+; CHECK-NEXT: call void @llvm.assume(i1 true) [ "dereferenceable"(ptr addrspace(1) [[P1]], i64 1023) ]
+; CHECK-NEXT: call void @llvm.assume(i1 true) [ "dereferenceable"(ptr addrspace(1) [[P2]], i64 1023) ]
+; CHECK-NEXT: br label %[[LOOP:.*]]
+; CHECK: [[LOOP]]:
+; CHECK-NEXT: [[INDEX:%.*]] = phi i32 [ 0, %[[ENTRY]] ], [ [[INDEX_NEXT:%.*]], %[[LOOP_INC:.*]] ]
+; CHECK-NEXT: [[GEP_P1:%.*]] = getelementptr inbounds i8, ptr addrspace(1) [[P1]], i32 [[INDEX]]
+; CHECK-NEXT: [[LD1:%.*]] = load i8, ptr addrspace(1) [[GEP_P1]], align 1
+; CHECK-NEXT: [[GEP_P2:%.*]] = getelementptr inbounds i8, ptr addrspace(1) [[P2]], i32 [[INDEX]]
+; CHECK-NEXT: [[LD2:%.*]] = load i8, ptr addrspace(1) [[GEP_P2]], align 1
+; CHECK-NEXT: [[C_0:%.*]] = icmp eq i8 [[LD1]], [[LD2]]
+; CHECK-NEXT: br i1 [[C_0]], label %[[LOOP_INC]], label %[[LOOP_END:.*]]
+; CHECK: [[LOOP_INC]]:
+; CHECK-NEXT: [[INDEX_NEXT]] = add i32 [[INDEX]], 1
+; CHECK-NEXT: [[EXITCOND:%.*]] = icmp ne i32 [[INDEX_NEXT]], 1024
+; CHECK-NEXT: br i1 [[EXITCOND]], label %[[LOOP]], label %[[LOOP_END]]
+; CHECK: [[LOOP_END]]:
+; CHECK-NEXT: [[RETVAL:%.*]] = phi i32 [ [[INDEX]], %[[LOOP]] ], [ -1, %[[LOOP_INC]] ]
+; CHECK-NEXT: ret i32 [[RETVAL]]
+;
+entry:
+ call void @llvm.assume(i1 true) [ "dereferenceable"(ptr addrspace(1) %p1, i64 1023) ]
+ call void @llvm.assume(i1 true) [ "dereferenceable"(ptr addrspace(1) %p2, i64 1023) ]
+ br label %loop.header
+
+loop.header:
+ %iv = phi i32 [ 0, %entry ], [ %iv.next, %loop.latch ]
+ %gep.p1 = getelementptr inbounds i8, ptr addrspace(1) %p1, i32 %iv
+ %ld1 = load i8, ptr addrspace(1) %gep.p1, align 1
+ %gep.p2 = getelementptr inbounds i8, ptr addrspace(1) %p2, i32 %iv
+ %ld2 = load i8, ptr addrspace(1) %gep.p2, align 1
+ %c.0 = icmp eq i8 %ld1, %ld2
+ br i1 %c.0, label %loop.latch, label %loop.end
+
+loop.latch:
+ %iv.next = add i32 %iv, 1
+ %exitcond = icmp ne i32 %iv.next, 1024
+ br i1 %exitcond, label %loop.header, label %loop.end
+
+loop.end:
+ %retval = phi i32 [ %iv, %loop.header ], [ -1, %loop.latch ]
+ ret i32 %retval
+}
More information about the llvm-commits
mailing list