[llvm] cffb8ae - [DEBUGINFO] Propagate debug metadata for sext SDNode. (#135971)

[via llvm-commits]

Author: Alexander Peskov
Date: 2025-05-02T08:31:41-04:00
New Revision: cffb8aee140ce0c022060941b7b60025dd70395c

URL: https://github.com/llvm/llvm-project/commit/cffb8aee140ce0c022060941b7b60025dd70395c
DIFF: https://github.com/llvm/llvm-project/commit/cffb8aee140ce0c022060941b7b60025dd70395c.diff

LOG: [DEBUGINFO] Propagate debug metadata for sext SDNode. (#135971)

In some cases of chained `sext` operators the debug metadata can be
missed. This patch propagates proper metadata to resulting node.

Particular case of issue is NVPTX codegen for function with bool local
variable:
```
void test(int i) {
  bool xyz = i == 0;
  foo(i);
}
```

---------

Signed-off-by: Alexander Peskov <apeskov at nvidia.com>

Added: 
    llvm/test/DebugInfo/NVPTX/debug-bool-var.ll

Modified: 
    llvm/lib/CodeGen/SelectionDAG/SelectionDAG.cpp

Removed: 
    


################################################################################
diff  --git a/llvm/lib/CodeGen/SelectionDAG/SelectionDAG.cpp b/llvm/lib/CodeGen/SelectionDAG/SelectionDAG.cpp
index d9d6d43c42430..2a68903c34cef 100644
--- a/llvm/lib/CodeGen/SelectionDAG/SelectionDAG.cpp
+++ b/llvm/lib/CodeGen/SelectionDAG/SelectionDAG.cpp
@@ -6352,7 +6352,9 @@ SDValue SelectionDAG::getNode(unsigned Opcode, const SDLoc &DL, EVT VT,
       SDNodeFlags Flags;
       if (OpOpcode == ISD::ZERO_EXTEND)
         Flags.setNonNeg(N1->getFlags().hasNonNeg());
-      return getNode(OpOpcode, DL, VT, N1.getOperand(0), Flags);
+      SDValue NewVal = getNode(OpOpcode, DL, VT, N1.getOperand(0), Flags);
+      transferDbgValues(N1, NewVal);
+      return NewVal;
     }
 
     if (OpOpcode == ISD::POISON)
@@ -6376,7 +6378,10 @@ SDValue SelectionDAG::getNode(unsigned Opcode, const SDLoc &DL, EVT VT,
     if (OpOpcode == ISD::ZERO_EXTEND) { // (zext (zext x)) -> (zext x)
       SDNodeFlags Flags;
       Flags.setNonNeg(N1->getFlags().hasNonNeg());
-      return getNode(ISD::ZERO_EXTEND, DL, VT, N1.getOperand(0), Flags);
+      SDValue NewVal =
+          getNode(ISD::ZERO_EXTEND, DL, VT, N1.getOperand(0), Flags);
+      transferDbgValues(N1, NewVal);
+      return NewVal;
     }
 
     if (OpOpcode == ISD::POISON)

diff  --git a/llvm/test/DebugInfo/NVPTX/debug-bool-var.ll b/llvm/test/DebugInfo/NVPTX/debug-bool-var.ll
new file mode 100644
index 0000000000000..7a42268650c63
--- /dev/null
+++ b/llvm/test/DebugInfo/NVPTX/debug-bool-var.ll
@@ -0,0 +1,70 @@
+; RUN: llc < %s -mtriple=nvptx64-nvidia-cuda -print-after=finalize-isel -o /dev/null 2>&1 | FileCheck %s
+
+declare void @foo(i32)
+
+define void @test1(i32 noundef %gid) !dbg !3 {
+entry:
+  ;
+  ; Equivalent of code:
+  ;   extern void foo(int);
+  ;   void test_kernel_bool(int a) {
+  ;     bool xyz = a == 0;
+  ;     foo(xyz);
+  ;   }
+  ;
+  ; CHECK-LABEL: Machine code for function test1
+  ; CHECK: DBG_VALUE %[[#]]:int32regs, $noreg, !"xyz", !DIExpression(), debug-location ![[#]]; test.cu:2 line no:6
+  ;
+  %cmp = icmp eq i32 %gid, 0, !dbg !12
+  %conv = zext i1 %cmp to i32, !dbg !12
+  %conv1 = trunc i32 %conv to i8, !dbg !12
+    #dbg_value(i8 %conv1, !10, !DIExpression(), !13)
+  %conv3 = sext i8 %conv1 to i32
+  call void @foo(i32 %conv3)
+  ret void
+}
+
+define void @test2(i32 noundef %gid) !dbg !14 {
+entry:
+  ;
+  ; Equivalent of code:
+  ;   extern void foo(int);
+  ;   void test_kernel_bool(int a) {
+  ;     unsigned char abc = a == 0;
+  ;     foo(abc);
+  ;   }
+  ;
+  ; CHECK-LABEL: Machine code for function test2
+  ; CHECK: DBG_VALUE %[[#]]:int32regs, $noreg, !"abc", !DIExpression(), debug-location ![[#]]; test.cu:12 line no:11
+  ;
+  %cmp = icmp eq i32 %gid, 0, !dbg !17
+  %conv = zext i1 %cmp to i32, !dbg !17
+  %conv1 = trunc i32 %conv to i8, !dbg !17
+    #dbg_value(i8 %conv1, !16, !DIExpression(), !18)
+  %conv3 = zext i8 %conv1 to i32
+  call void @foo(i32 %conv3)
+  ret void
+}
+
+!llvm.dbg.cu = !{!0}
+!llvm.module.flags = !{!2}
+
+!0 = distinct !DICompileUnit(language: DW_LANG_C_plus_plus, file: !1, producer: "", isOptimized: false, runtimeVersion: 0, emissionKind: FullDebug)
+!1 = !DIFile(filename: "test.cu", directory: "/source/dir")
+!2 = !{i32 1, !"Debug Info Version", i32 3}
+!3 = distinct !DISubprogram(name: "test1", linkageName: "_test1i", scope: !1, file: !1, line: 5, type: !4, scopeLine: 5, unit: !0, retainedNodes: !8)
+!4 = !DISubroutineType(types: !5)
+!5 = !{!6, !7}
+!6 = !DIBasicType(tag: DW_TAG_unspecified_type, name: "void")
+!7 = !DIBasicType(name: "int", size: 32, encoding: DW_ATE_signed)
+!8 = !{}
+!9 = distinct !DILexicalBlock(scope: !3, file: !1, line: 5, column: 30)
+!10 = !DILocalVariable(name: "xyz", scope: !9, file: !1, line: 6, type: !11)
+!11 = !DIBasicType(name: "bool", size: 8, encoding: DW_ATE_boolean)
+!12 = !DILocation(line: 1, column: 3, scope: !9)
+!13 = !DILocation(line: 2, scope: !9)
+!14 = distinct !DISubprogram(name: "test2", linkageName: "_test2i", scope: !1, file: !1, line: 10, type: !4, scopeLine: 10, unit: !0, retainedNodes: !8)
+!15 = distinct !DILexicalBlock(scope: !14, file: !1, line: 10, column: 30)
+!16 = !DILocalVariable(name: "abc", scope: !15, file: !1, line: 11, type: !11)
+!17 = !DILocation(line: 11, column: 3, scope: !15)
+!18 = !DILocation(line: 12, scope: !15)