[llvm] [TableGen] Add `!instances` operator to get defined records (PR #129680)

[Artem Belevich via llvm-commits]

================
@@ -0,0 +1,134 @@
+// RUN: llvm-tblgen %s | FileCheck %s
+// RUN: not llvm-tblgen -DERROR1 %s 2>&1 | FileCheck --check-prefix=ERROR1 %s
+// RUN: not llvm-tblgen -DERROR2 %s 2>&1 | FileCheck --check-prefix=ERROR2 %s
+// RUN: not llvm-tblgen -DERROR3 %s 2>&1 | FileCheck --check-prefix=ERROR3 %s
+// XFAIL: vg_leak
+
+class A;
+def a0 : A;
+def a1 : A;
+
+class B : A;
+def b0 : B;
+def b1 : B;
+
+// CHECK-LABEL: def test0_instances_A {
+// CHECK-NEXT:    list<A> instances = [a0, a1, b0, b1];
+// CHECK-NEXT:  }
+def test0_instances_A {
+  list<A> instances = !instances<A>();
+}
+
+// CHECK-LABEL: def test1_instances_A_x0 {
+// CHECK-NEXT:    list<A> instances = [a0, b0];
+// CHECK-NEXT:  }
+def test1_instances_A_x0 {
+  list<A> instances = !instances<A>(".*0");
+}
+
+// CHECK-LABEL: def test2_instances_A_x1 {
+// CHECK-NEXT:    list<A> instances = [a1, b1];
+// CHECK-NEXT:  }
+def test2_instances_A_x1 {
+  list<A> instances = !instances<A>(".*1");
+}
+
+// CHECK-LABEL: def test3_instances_B {
+// CHECK-NEXT:    list<B> instances = [b0, b1];
+// CHECK-NEXT:  }
+def test3_instances_B {
+  list<B> instances = !instances<B>();
+}
+
+//-----------------------------------------------------------------------------//
+
+def a2 : A;
+def b2 : B;
+
+class ClassTest {
+   list<A> instances_A = !instances<A>();
+   list<B> instances_B = !instances<B>();
+}
+
+def a3 : A;
+def b3 : B;
+
+def test4_in_class_def : ClassTest;
+// CHECK-LABEL: def test4_in_class_def {
+// CHECK-NEXT:    list<A> instances_A = [a0, a1, a2, a3, b0, b1, b2, b3];
+// CHECK-NEXT:    list<B> instances_B = [b0, b1, b2, b3];
+// CHECK-NEXT:  }
+
+//-----------------------------------------------------------------------------//
+// Self-recurrence is not supported, so it won't be count in.
+
+// CHECK-LABEL: def test5_self_recurrence {
+// CHECK-NEXT:    list<A> instances_A = [a0, a1, a2, a3, b0, b1, b2, b3];
+// CHECK-NEXT:  }
+def test5_self_recurrence : A {
+   list<A> instances_A = !instances<A>();
+}
+
+//-----------------------------------------------------------------------------//
+// Test these in multiclasses/loops.
+
+class C {
+  list<C> instances_C = !instances<C>();
+}
+
+multiclass MultiClassTest {
+  foreach i = 0-2 in {
+    def "c"#i : C;
+  }
+}
+
+// CHECK-LABEL: def test6_in_multiclass_def_c0 {
+// CHECK-NEXT:    list<C> instances_C = [];
+// CHECK-NEXT:  }
+// CHECK-LABEL: def test6_in_multiclass_def_c1 {
+// CHECK-NEXT:    list<C> instances_C = [test6_in_multiclass_def_c0];
+// CHECK-NEXT:  }
+// CHECK-LABEL: def test6_in_multiclass_def_c2 {
+// CHECK-NEXT:    list<C> instances_C = [test6_in_multiclass_def_c0, test6_in_multiclass_def_c1];
+// CHECK-NEXT:  }
+defm test6_in_multiclass_def_ : MultiClassTest;
+
+//-----------------------------------------------------------------------------//
+// Default argument will be considered as well.
+
+class TestArgument<B b = B<>> {
+  list<B> instances_B = !instances<B>();
+}
+
+// CHECK-LABEL: def test7_default_arg {
+// CHECK-NEXT:    list<B> instances_B = [anonymous_0, b0, b1, b2, b3];
+// CHECK-NEXT:  }
+def test7_default_arg : TestArgument;
+
+// Temporary actual parameter won't be considered.
----------------
Artem-B wrote:

This sounds counter-intuitive. For the instantiation of `TestArgument` both default or explicitly provided argument look exectly the same -- the value record exists in both acases. Capturing it in case of the value coming from the default argument, but not for the actual argument looks inconsistent to me. I think behavior should be the same in both cases.


https://github.com/llvm/llvm-project/pull/129680