[llvm] [InstCombine] Fold `select (A &/| B), T, F` if `select B, T, F` is foldable (PR #76621)
Yingwei Zheng via llvm-commits
llvm-commits at lists.llvm.org
Sun Dec 31 00:55:38 PST 2023
https://github.com/dtcxzyw updated https://github.com/llvm/llvm-project/pull/76621
>From f06526bc146efd48971150eeeb740508d6be13bc Mon Sep 17 00:00:00 2001
From: Yingwei Zheng <dtcxzyw2333 at gmail.com>
Date: Sun, 31 Dec 2023 16:44:56 +0800
Subject: [PATCH 1/2] [InstCombine] Add pre-commit tests. NFC.
---
.../Transforms/InstCombine/select-and-or.ll | 378 ++++++++++++++++++
1 file changed, 378 insertions(+)
diff --git a/llvm/test/Transforms/InstCombine/select-and-or.ll b/llvm/test/Transforms/InstCombine/select-and-or.ll
index 7edcd767b86ecb..688084f60daa15 100644
--- a/llvm/test/Transforms/InstCombine/select-and-or.ll
+++ b/llvm/test/Transforms/InstCombine/select-and-or.ll
@@ -965,3 +965,381 @@ define i1 @or_and3_wrong_operand(i1 %a, i1 %b, i32 %x, i32 %y, i1 %d) {
%r = select i1 %cond, i1 %d, i1 %b
ret i1 %r
}
+
+define i8 @test_or_umax(i8 %x, i8 %y, i1 %cond) {
+; CHECK-LABEL: @test_or_umax(
+; CHECK-NEXT: [[CMP:%.*]] = icmp ugt i8 [[X:%.*]], [[Y:%.*]]
+; CHECK-NEXT: [[OR:%.*]] = select i1 [[COND:%.*]], i1 true, i1 [[CMP]]
+; CHECK-NEXT: [[RET:%.*]] = select i1 [[OR]], i8 [[X]], i8 [[Y]]
+; CHECK-NEXT: ret i8 [[RET]]
+;
+ %cmp = icmp ugt i8 %x, %y
+ %or = select i1 %cond, i1 true, i1 %cmp
+ %ret = select i1 %or, i8 %x, i8 %y
+ ret i8 %ret
+}
+
+define i8 @test_or_umin(i8 %x, i8 %y, i1 %cond) {
+; CHECK-LABEL: @test_or_umin(
+; CHECK-NEXT: [[CMP:%.*]] = icmp ugt i8 [[X:%.*]], [[Y:%.*]]
+; CHECK-NEXT: [[OR:%.*]] = select i1 [[COND:%.*]], i1 true, i1 [[CMP]]
+; CHECK-NEXT: [[RET:%.*]] = select i1 [[OR]], i8 [[Y]], i8 [[X]]
+; CHECK-NEXT: ret i8 [[RET]]
+;
+ %cmp = icmp ugt i8 %x, %y
+ %or = select i1 %cond, i1 true, i1 %cmp
+ %ret = select i1 %or, i8 %y, i8 %x
+ ret i8 %ret
+}
+
+define i8 @test_and_umax(i8 %x, i8 %y, i1 %cond) {
+; CHECK-LABEL: @test_and_umax(
+; CHECK-NEXT: [[CMP:%.*]] = icmp ugt i8 [[X:%.*]], [[Y:%.*]]
+; CHECK-NEXT: [[AND:%.*]] = select i1 [[COND:%.*]], i1 [[CMP]], i1 false
+; CHECK-NEXT: [[RET:%.*]] = select i1 [[AND]], i8 [[X]], i8 [[Y]]
+; CHECK-NEXT: ret i8 [[RET]]
+;
+ %cmp = icmp ugt i8 %x, %y
+ %and = select i1 %cond, i1 %cmp, i1 false
+ %ret = select i1 %and, i8 %x, i8 %y
+ ret i8 %ret
+}
+
+define i8 @test_and_umin(i8 %x, i8 %y, i1 %cond) {
+; CHECK-LABEL: @test_and_umin(
+; CHECK-NEXT: [[CMP:%.*]] = icmp ugt i8 [[X:%.*]], [[Y:%.*]]
+; CHECK-NEXT: [[AND:%.*]] = select i1 [[COND:%.*]], i1 [[CMP]], i1 false
+; CHECK-NEXT: [[RET:%.*]] = select i1 [[AND]], i8 [[Y]], i8 [[X]]
+; CHECK-NEXT: ret i8 [[RET]]
+;
+ %cmp = icmp ugt i8 %x, %y
+ %and = select i1 %cond, i1 %cmp, i1 false
+ %ret = select i1 %and, i8 %y, i8 %x
+ ret i8 %ret
+}
+
+define i8 @test_or_umax_bitwise1(i8 %x, i8 %y, i8 %val) {
+; CHECK-LABEL: @test_or_umax_bitwise1(
+; CHECK-NEXT: [[COND:%.*]] = icmp eq i8 [[VAL:%.*]], 0
+; CHECK-NEXT: [[CMP:%.*]] = icmp ugt i8 [[X:%.*]], [[Y:%.*]]
+; CHECK-NEXT: [[OR:%.*]] = or i1 [[COND]], [[CMP]]
+; CHECK-NEXT: [[RET:%.*]] = select i1 [[OR]], i8 [[X]], i8 [[Y]]
+; CHECK-NEXT: ret i8 [[RET]]
+;
+ %cond = icmp eq i8 %val, 0 ; thwart complexity-based ordering
+ %cmp = icmp ugt i8 %x, %y
+ %or = or i1 %cond, %cmp
+ %ret = select i1 %or, i8 %x, i8 %y
+ ret i8 %ret
+}
+
+define i8 @test_or_umax_bitwise2(i8 %x, i8 %y, i8 %val) {
+; CHECK-LABEL: @test_or_umax_bitwise2(
+; CHECK-NEXT: [[COND:%.*]] = icmp eq i8 [[VAL:%.*]], 0
+; CHECK-NEXT: [[CMP:%.*]] = icmp ugt i8 [[X:%.*]], [[Y:%.*]]
+; CHECK-NEXT: [[OR:%.*]] = or i1 [[CMP]], [[COND]]
+; CHECK-NEXT: [[RET:%.*]] = select i1 [[OR]], i8 [[X]], i8 [[Y]]
+; CHECK-NEXT: ret i8 [[RET]]
+;
+ %cond = icmp eq i8 %val, 0 ; thwart complexity-based ordering
+ %cmp = icmp ugt i8 %x, %y
+ %or = or i1 %cmp, %cond
+ %ret = select i1 %or, i8 %x, i8 %y
+ ret i8 %ret
+}
+
+define i8 @test_and_umax_bitwise1(i8 %x, i8 %y, i8 %val) {
+; CHECK-LABEL: @test_and_umax_bitwise1(
+; CHECK-NEXT: [[COND:%.*]] = icmp eq i8 [[VAL:%.*]], 0
+; CHECK-NEXT: [[CMP:%.*]] = icmp ugt i8 [[X:%.*]], [[Y:%.*]]
+; CHECK-NEXT: [[AND:%.*]] = and i1 [[COND]], [[CMP]]
+; CHECK-NEXT: [[RET:%.*]] = select i1 [[AND]], i8 [[X]], i8 [[Y]]
+; CHECK-NEXT: ret i8 [[RET]]
+;
+ %cond = icmp eq i8 %val, 0 ; thwart complexity-based ordering
+ %cmp = icmp ugt i8 %x, %y
+ %and = and i1 %cond, %cmp
+ %ret = select i1 %and, i8 %x, i8 %y
+ ret i8 %ret
+}
+
+define i8 @test_and_umax_bitwise2(i8 %x, i8 %y, i8 %val) {
+; CHECK-LABEL: @test_and_umax_bitwise2(
+; CHECK-NEXT: [[COND:%.*]] = icmp eq i8 [[VAL:%.*]], 0
+; CHECK-NEXT: [[CMP:%.*]] = icmp ugt i8 [[X:%.*]], [[Y:%.*]]
+; CHECK-NEXT: [[AND:%.*]] = and i1 [[CMP]], [[COND]]
+; CHECK-NEXT: [[RET:%.*]] = select i1 [[AND]], i8 [[X]], i8 [[Y]]
+; CHECK-NEXT: ret i8 [[RET]]
+;
+ %cond = icmp eq i8 %val, 0 ; thwart complexity-based ordering
+ %cmp = icmp ugt i8 %x, %y
+ %and = and i1 %cmp, %cond
+ %ret = select i1 %and, i8 %x, i8 %y
+ ret i8 %ret
+}
+
+; Other SPFs
+
+define i8 @test_or_smax(i8 %x, i8 %y, i1 %cond) {
+; CHECK-LABEL: @test_or_smax(
+; CHECK-NEXT: [[CMP:%.*]] = icmp sgt i8 [[X:%.*]], [[Y:%.*]]
+; CHECK-NEXT: [[OR:%.*]] = select i1 [[COND:%.*]], i1 true, i1 [[CMP]]
+; CHECK-NEXT: [[RET:%.*]] = select i1 [[OR]], i8 [[X]], i8 [[Y]]
+; CHECK-NEXT: ret i8 [[RET]]
+;
+ %cmp = icmp sgt i8 %x, %y
+ %or = select i1 %cond, i1 true, i1 %cmp
+ %ret = select i1 %or, i8 %x, i8 %y
+ ret i8 %ret
+}
+
+define i8 @test_or_abs(i8 %x, i1 %cond) {
+; CHECK-LABEL: @test_or_abs(
+; CHECK-NEXT: [[CMP:%.*]] = icmp sgt i8 [[X:%.*]], -1
+; CHECK-NEXT: [[NEG:%.*]] = sub nsw i8 0, [[X]]
+; CHECK-NEXT: [[OR:%.*]] = select i1 [[COND:%.*]], i1 true, i1 [[CMP]]
+; CHECK-NEXT: [[RET:%.*]] = select i1 [[OR]], i8 [[X]], i8 [[NEG]]
+; CHECK-NEXT: ret i8 [[RET]]
+;
+ %cmp = icmp sgt i8 %x, -1
+ %neg = sub nsw i8 0, %x
+ %or = select i1 %cond, i1 true, i1 %cmp
+ %ret = select i1 %or, i8 %x, i8 %neg
+ ret i8 %ret
+}
+
+; TODO: fold SPF_FMAXNUM
+define float @test_or_fmaxnum(float %x, float %y, i1 %cond) {
+; CHECK-LABEL: @test_or_fmaxnum(
+; CHECK-NEXT: [[CMP:%.*]] = fcmp nnan ogt float [[X:%.*]], [[Y:%.*]]
+; CHECK-NEXT: [[OR:%.*]] = select i1 [[COND:%.*]], i1 true, i1 [[CMP]]
+; CHECK-NEXT: [[RET:%.*]] = select i1 [[OR]], float [[X]], float [[Y]]
+; CHECK-NEXT: ret float [[RET]]
+;
+ %cmp = fcmp nnan ogt float %x, %y
+ %or = select i1 %cond, i1 true, i1 %cmp
+ %ret = select i1 %or, float %x, float %y
+ ret float %ret
+}
+
+; Negative tests
+
+define i8 @test_or_umax_invalid_logical(i8 %x, i8 %y, i1 %cond) {
+; CHECK-LABEL: @test_or_umax_invalid_logical(
+; CHECK-NEXT: [[CMP:%.*]] = icmp ugt i8 [[X:%.*]], [[Y:%.*]]
+; CHECK-NEXT: [[OR:%.*]] = select i1 [[CMP]], i1 true, i1 [[COND:%.*]]
+; CHECK-NEXT: [[RET:%.*]] = select i1 [[OR]], i8 [[X]], i8 [[Y]]
+; CHECK-NEXT: ret i8 [[RET]]
+;
+ %cmp = icmp ugt i8 %x, %y
+ %or = select i1 %cmp, i1 true, i1 %cond
+ %ret = select i1 %or, i8 %x, i8 %y
+ ret i8 %ret
+}
+
+define i8 @test_and_umax_invalid_logical(i8 %x, i8 %y, i1 %cond) {
+; CHECK-LABEL: @test_and_umax_invalid_logical(
+; CHECK-NEXT: [[CMP:%.*]] = icmp ugt i8 [[X:%.*]], [[Y:%.*]]
+; CHECK-NEXT: [[AND:%.*]] = select i1 [[CMP]], i1 [[COND:%.*]], i1 false
+; CHECK-NEXT: [[RET:%.*]] = select i1 [[AND]], i8 [[X]], i8 [[Y]]
+; CHECK-NEXT: ret i8 [[RET]]
+;
+ %cmp = icmp ugt i8 %x, %y
+ %and = select i1 %cmp, i1 %cond, i1 false
+ %ret = select i1 %and, i8 %x, i8 %y
+ ret i8 %ret
+}
+
+define i8 @test_or_umax_multiuse_cond(i8 %x, i8 %y, i1 %cond) {
+; CHECK-LABEL: @test_or_umax_multiuse_cond(
+; CHECK-NEXT: [[CMP:%.*]] = icmp ugt i8 [[X:%.*]], [[Y:%.*]]
+; CHECK-NEXT: [[OR:%.*]] = select i1 [[COND:%.*]], i1 true, i1 [[CMP]]
+; CHECK-NEXT: call void @use(i1 [[OR]])
+; CHECK-NEXT: [[RET:%.*]] = select i1 [[OR]], i8 [[X]], i8 [[Y]]
+; CHECK-NEXT: ret i8 [[RET]]
+;
+ %cmp = icmp ugt i8 %x, %y
+ %or = select i1 %cond, i1 true, i1 %cmp
+ call void @use(i1 %or)
+ %ret = select i1 %or, i8 %x, i8 %y
+ ret i8 %ret
+}
+
+; Tests from PR76203
+
+define i8 @test_or_eq_a_b(i1 %other_cond, i8 %a, i8 %b) {
+; CHECK-LABEL: @test_or_eq_a_b(
+; CHECK-NEXT: [[CMP:%.*]] = icmp eq i8 [[A:%.*]], [[B:%.*]]
+; CHECK-NEXT: [[COND:%.*]] = or i1 [[CMP]], [[OTHER_COND:%.*]]
+; CHECK-NEXT: [[SELECT:%.*]] = select i1 [[COND]], i8 [[A]], i8 [[B]]
+; CHECK-NEXT: ret i8 [[SELECT]]
+;
+ %cmp = icmp eq i8 %a, %b
+ %cond = or i1 %other_cond, %cmp
+ %select = select i1 %cond, i8 %a, i8 %b
+ ret i8 %select
+}
+
+define i8 @test_and_ne_a_b(i1 %other_cond, i8 %a, i8 %b) {
+; CHECK-LABEL: @test_and_ne_a_b(
+; CHECK-NEXT: [[CMP:%.*]] = icmp ne i8 [[A:%.*]], [[B:%.*]]
+; CHECK-NEXT: [[COND:%.*]] = and i1 [[CMP]], [[OTHER_COND:%.*]]
+; CHECK-NEXT: [[SELECT:%.*]] = select i1 [[COND]], i8 [[A]], i8 [[B]]
+; CHECK-NEXT: ret i8 [[SELECT]]
+;
+ %cmp = icmp ne i8 %a, %b
+ %cond = and i1 %other_cond, %cmp
+ %select = select i1 %cond, i8 %a, i8 %b
+ ret i8 %select
+}
+
+define i8 @test_or_eq_a_b_commuted(i1 %other_cond, i8 %a, i8 %b) {
+; CHECK-LABEL: @test_or_eq_a_b_commuted(
+; CHECK-NEXT: [[CMP:%.*]] = icmp eq i8 [[A:%.*]], [[B:%.*]]
+; CHECK-NEXT: [[COND:%.*]] = or i1 [[CMP]], [[OTHER_COND:%.*]]
+; CHECK-NEXT: [[SELECT:%.*]] = select i1 [[COND]], i8 [[B]], i8 [[A]]
+; CHECK-NEXT: ret i8 [[SELECT]]
+;
+ %cmp = icmp eq i8 %a, %b
+ %cond = or i1 %other_cond, %cmp
+ %select = select i1 %cond, i8 %b, i8 %a
+ ret i8 %select
+}
+
+define i8 @test_and_ne_a_b_commuted(i1 %other_cond, i8 %a, i8 %b) {
+; CHECK-LABEL: @test_and_ne_a_b_commuted(
+; CHECK-NEXT: [[CMP:%.*]] = icmp ne i8 [[A:%.*]], [[B:%.*]]
+; CHECK-NEXT: [[COND:%.*]] = and i1 [[CMP]], [[OTHER_COND:%.*]]
+; CHECK-NEXT: [[SELECT:%.*]] = select i1 [[COND]], i8 [[B]], i8 [[A]]
+; CHECK-NEXT: ret i8 [[SELECT]]
+;
+ %cmp = icmp ne i8 %a, %b
+ %cond = and i1 %other_cond, %cmp
+ %select = select i1 %cond, i8 %b, i8 %a
+ ret i8 %select
+}
+
+define i8 @test_or_eq_different_operands(i8 %a, i8 %b, i8 %c) {
+; CHECK-LABEL: @test_or_eq_different_operands(
+; CHECK-NEXT: [[CMP:%.*]] = icmp eq i8 [[A:%.*]], [[C:%.*]]
+; CHECK-NEXT: [[CMP1:%.*]] = icmp eq i8 [[B:%.*]], [[A]]
+; CHECK-NEXT: [[COND:%.*]] = or i1 [[CMP]], [[CMP1]]
+; CHECK-NEXT: [[SELECT:%.*]] = select i1 [[COND]], i8 [[A]], i8 [[B]]
+; CHECK-NEXT: ret i8 [[SELECT]]
+;
+ %cmp = icmp eq i8 %a, %c
+ %cmp1 = icmp eq i8 %b, %a
+ %cond = or i1 %cmp, %cmp1
+ %select = select i1 %cond, i8 %a, i8 %b
+ ret i8 %select
+}
+
+define i8 @test_or_eq_a_b_multi_use(i1 %other_cond, i8 %a, i8 %b) {
+; CHECK-LABEL: @test_or_eq_a_b_multi_use(
+; CHECK-NEXT: [[CMP:%.*]] = icmp eq i8 [[A:%.*]], [[B:%.*]]
+; CHECK-NEXT: [[COND:%.*]] = or i1 [[CMP]], [[OTHER_COND:%.*]]
+; CHECK-NEXT: call void @use(i1 [[CMP]])
+; CHECK-NEXT: call void @use(i1 [[COND]])
+; CHECK-NEXT: [[SELECT:%.*]] = select i1 [[COND]], i8 [[A]], i8 [[B]]
+; CHECK-NEXT: ret i8 [[SELECT]]
+;
+ %cmp = icmp eq i8 %a, %b
+ %cond = or i1 %other_cond, %cmp
+ call void @use(i1 %cmp)
+ call void @use(i1 %cond)
+ %select = select i1 %cond, i8 %a, i8 %b
+ ret i8 %select
+}
+
+define <2 x i8> @test_or_eq_a_b_vec(<2 x i1> %other_cond, <2 x i8> %a, <2 x i8> %b) {
+; CHECK-LABEL: @test_or_eq_a_b_vec(
+; CHECK-NEXT: [[CMP:%.*]] = icmp eq <2 x i8> [[A:%.*]], [[B:%.*]]
+; CHECK-NEXT: [[COND:%.*]] = or <2 x i1> [[CMP]], [[OTHER_COND:%.*]]
+; CHECK-NEXT: [[SELECT:%.*]] = select <2 x i1> [[COND]], <2 x i8> [[A]], <2 x i8> [[B]]
+; CHECK-NEXT: ret <2 x i8> [[SELECT]]
+;
+ %cmp = icmp eq <2 x i8> %a, %b
+ %cond = or <2 x i1> %other_cond, %cmp
+ %select = select <2 x i1> %cond, <2 x i8> %a, <2 x i8> %b
+ ret <2 x i8> %select
+}
+
+define i8 @test_or_ne_a_b(i1 %other_cond, i8 %a, i8 %b) {
+; CHECK-LABEL: @test_or_ne_a_b(
+; CHECK-NEXT: [[CMP:%.*]] = icmp ne i8 [[A:%.*]], [[B:%.*]]
+; CHECK-NEXT: [[COND:%.*]] = or i1 [[CMP]], [[OTHER_COND:%.*]]
+; CHECK-NEXT: [[SELECT:%.*]] = select i1 [[COND]], i8 [[A]], i8 [[B]]
+; CHECK-NEXT: ret i8 [[SELECT]]
+;
+ %cmp = icmp ne i8 %a, %b
+ %cond = or i1 %other_cond, %cmp
+ %select = select i1 %cond, i8 %a, i8 %b
+ ret i8 %select
+}
+
+define i8 @test_and_ne_different_operands_fail(i8 %a, i8 %b, i8 %c) {
+; CHECK-LABEL: @test_and_ne_different_operands_fail(
+; CHECK-NEXT: [[CMP:%.*]] = icmp ne i8 [[A:%.*]], [[C:%.*]]
+; CHECK-NEXT: [[CMP1:%.*]] = icmp ne i8 [[B:%.*]], [[C]]
+; CHECK-NEXT: [[COND:%.*]] = and i1 [[CMP]], [[CMP1]]
+; CHECK-NEXT: [[SELECT:%.*]] = select i1 [[COND]], i8 [[B]], i8 [[A]]
+; CHECK-NEXT: ret i8 [[SELECT]]
+;
+ %cmp = icmp ne i8 %a, %c
+ %cmp1 = icmp ne i8 %b, %c
+ %cond = and i1 %cmp, %cmp1
+ %select = select i1 %cond, i8 %b, i8 %a
+ ret i8 %select
+}
+
+define i8 @test_logical_or_eq_a_b(i1 %other_cond, i8 %a, i8 %b) {
+; CHECK-LABEL: @test_logical_or_eq_a_b(
+; CHECK-NEXT: [[CMP:%.*]] = icmp eq i8 [[A:%.*]], [[B:%.*]]
+; CHECK-NEXT: [[OR_COND:%.*]] = select i1 [[OTHER_COND:%.*]], i1 true, i1 [[CMP]]
+; CHECK-NEXT: [[SELECT:%.*]] = select i1 [[OR_COND]], i8 [[A]], i8 [[B]]
+; CHECK-NEXT: ret i8 [[SELECT]]
+;
+ %cmp = icmp eq i8 %a, %b
+ %or.cond = select i1 %other_cond, i1 true, i1 %cmp
+ %select = select i1 %or.cond, i8 %a, i8 %b
+ ret i8 %select
+}
+
+define i8 @test_logical_commuted_or_eq_a_b(i1 %other_cond, i8 %a, i8 %b) {
+; CHECK-LABEL: @test_logical_commuted_or_eq_a_b(
+; CHECK-NEXT: [[CMP:%.*]] = icmp eq i8 [[A:%.*]], [[B:%.*]]
+; CHECK-NEXT: [[OR_COND:%.*]] = select i1 [[CMP]], i1 true, i1 [[OTHER_COND:%.*]]
+; CHECK-NEXT: [[SELECT:%.*]] = select i1 [[OR_COND]], i8 [[A]], i8 [[B]]
+; CHECK-NEXT: ret i8 [[SELECT]]
+;
+ %cmp = icmp eq i8 %a, %b
+ %or.cond = select i1 %cmp, i1 true, i1 %other_cond
+ %select = select i1 %or.cond, i8 %a, i8 %b
+ ret i8 %select
+}
+
+define i8 @test_logical_and_ne_a_b(i1 %other_cond, i8 %a, i8 %b) {
+; CHECK-LABEL: @test_logical_and_ne_a_b(
+; CHECK-NEXT: [[CMP:%.*]] = icmp ne i8 [[A:%.*]], [[B:%.*]]
+; CHECK-NEXT: [[OR_COND:%.*]] = select i1 [[OTHER_COND:%.*]], i1 [[CMP]], i1 false
+; CHECK-NEXT: [[SELECT:%.*]] = select i1 [[OR_COND]], i8 [[A]], i8 [[B]]
+; CHECK-NEXT: ret i8 [[SELECT]]
+;
+ %cmp = icmp ne i8 %a, %b
+ %or.cond = select i1 %other_cond, i1 %cmp, i1 false
+ %select = select i1 %or.cond, i8 %a, i8 %b
+ ret i8 %select
+}
+
+define i8 @test_logical_commuted_and_ne_a_b(i1 %other_cond, i8 %a, i8 %b) {
+; CHECK-LABEL: @test_logical_commuted_and_ne_a_b(
+; CHECK-NEXT: [[CMP:%.*]] = icmp ne i8 [[A:%.*]], [[B:%.*]]
+; CHECK-NEXT: [[OR_COND:%.*]] = select i1 [[CMP]], i1 [[OTHER_COND:%.*]], i1 false
+; CHECK-NEXT: [[SELECT:%.*]] = select i1 [[OR_COND]], i8 [[A]], i8 [[B]]
+; CHECK-NEXT: ret i8 [[SELECT]]
+;
+ %cmp = icmp ne i8 %a, %b
+ %or.cond = select i1 %cmp, i1 %other_cond, i1 false
+ %select = select i1 %or.cond, i8 %a, i8 %b
+ ret i8 %select
+}
>From ff104ef9af4021da99441eaaa7b5a304ab1f0785 Mon Sep 17 00:00:00 2001
From: Yingwei Zheng <dtcxzyw2333 at gmail.com>
Date: Sun, 31 Dec 2023 16:47:28 +0800
Subject: [PATCH 2/2] [InstCombine] Fold `select (A &/| B), T, F` if `select B,
T, F` is foldable
---
.../InstCombine/InstCombineSelect.cpp | 46 ++++++
.../Transforms/InstCombine/select-and-or.ll | 138 +++++++-----------
.../InstCombine/select-factorize.ll | 10 +-
.../Transforms/InstCombine/zext-or-icmp.ll | 8 +-
llvm/test/Transforms/Reassociate/basictest.ll | 4 +-
5 files changed, 109 insertions(+), 97 deletions(-)
diff --git a/llvm/lib/Transforms/InstCombine/InstCombineSelect.cpp b/llvm/lib/Transforms/InstCombine/InstCombineSelect.cpp
index aa3397d086be33..cf66f5be2d408f 100644
--- a/llvm/lib/Transforms/InstCombine/InstCombineSelect.cpp
+++ b/llvm/lib/Transforms/InstCombine/InstCombineSelect.cpp
@@ -3794,5 +3794,51 @@ Instruction *InstCombinerImpl::visitSelectInst(SelectInst &SI) {
if (Instruction *I = foldBitCeil(SI, Builder))
return I;
+ // Fold:
+ // (select A && B, T, F) -> (select A, (select B, T, F), F)
+ // (select A || B, T, F) -> (select A, T, (select B, T, F))
+ // if (select B, T, F) is foldable.
+ // TODO: preserve FMF flags
+ auto FoldSelectWithAndOrCond = [&](bool IsAnd, Value *A,
+ Value *B) -> Instruction * {
+ if (Value *V = simplifySelectInst(B, TrueVal, FalseVal,
+ SQ.getWithInstruction(&SI)))
+ return SelectInst::Create(A, IsAnd ? V : TrueVal, IsAnd ? FalseVal : V);
+
+ // Is (select B, T, F) a SPF?
+ if (CondVal->hasOneUse() && SelType->isIntOrIntVectorTy()) {
+ Value *LHS, *RHS;
+ if (ICmpInst *Cmp = dyn_cast<ICmpInst>(B))
+ if (Value *V = canonicalizeSPF(*Cmp, TrueVal, FalseVal, *this))
+ return SelectInst::Create(A, IsAnd ? V : TrueVal,
+ IsAnd ? FalseVal : V);
+ }
+
+ return nullptr;
+ };
+
+ Value *LHS, *RHS;
+ if (match(CondVal, m_And(m_Value(LHS), m_Value(RHS)))) {
+ if (Instruction *I = FoldSelectWithAndOrCond(/*IsAnd*/ true, LHS, RHS))
+ return I;
+ if (Instruction *I = FoldSelectWithAndOrCond(/*IsAnd*/ true, RHS, LHS))
+ return I;
+ } else if (match(CondVal, m_Or(m_Value(LHS), m_Value(RHS)))) {
+ if (Instruction *I = FoldSelectWithAndOrCond(/*IsAnd*/ false, LHS, RHS))
+ return I;
+ if (Instruction *I = FoldSelectWithAndOrCond(/*IsAnd*/ false, RHS, LHS))
+ return I;
+ } else {
+ // We cannot swap the operands of logical and/or.
+ // TODO: Can we swap the operands by inserting a freeze?
+ if (match(CondVal, m_LogicalAnd(m_Value(LHS), m_Value(RHS)))) {
+ if (Instruction *I = FoldSelectWithAndOrCond(/*IsAnd*/ true, LHS, RHS))
+ return I;
+ } else if (match(CondVal, m_LogicalOr(m_Value(LHS), m_Value(RHS)))) {
+ if (Instruction *I = FoldSelectWithAndOrCond(/*IsAnd*/ false, LHS, RHS))
+ return I;
+ }
+ }
+
return nullptr;
}
diff --git a/llvm/test/Transforms/InstCombine/select-and-or.ll b/llvm/test/Transforms/InstCombine/select-and-or.ll
index 688084f60daa15..0f7acd4d56c064 100644
--- a/llvm/test/Transforms/InstCombine/select-and-or.ll
+++ b/llvm/test/Transforms/InstCombine/select-and-or.ll
@@ -613,9 +613,9 @@ define i1 @and_or2_wrong_operand(i1 %a, i1 %b, i1 %c, i1 %d) {
define i1 @and_or3(i1 %a, i1 %b, i32 %x, i32 %y) {
; CHECK-LABEL: @and_or3(
-; CHECK-NEXT: [[C:%.*]] = icmp ne i32 [[X:%.*]], [[Y:%.*]]
-; CHECK-NEXT: [[TMP1:%.*]] = select i1 [[C]], i1 true, i1 [[A:%.*]]
-; CHECK-NEXT: [[R:%.*]] = select i1 [[B:%.*]], i1 [[TMP1]], i1 false
+; CHECK-NEXT: [[TMP1:%.*]] = icmp ne i32 [[X:%.*]], [[Y:%.*]]
+; CHECK-NEXT: [[TMP2:%.*]] = select i1 [[TMP1]], i1 true, i1 [[A:%.*]]
+; CHECK-NEXT: [[R:%.*]] = select i1 [[B:%.*]], i1 [[TMP2]], i1 false
; CHECK-NEXT: ret i1 [[R]]
;
%c = icmp eq i32 %x, %y
@@ -626,9 +626,9 @@ define i1 @and_or3(i1 %a, i1 %b, i32 %x, i32 %y) {
define i1 @and_or3_commuted(i1 %a, i1 %b, i32 %x, i32 %y) {
; CHECK-LABEL: @and_or3_commuted(
-; CHECK-NEXT: [[C:%.*]] = icmp ne i32 [[X:%.*]], [[Y:%.*]]
-; CHECK-NEXT: [[TMP1:%.*]] = select i1 [[C]], i1 true, i1 [[A:%.*]]
-; CHECK-NEXT: [[R:%.*]] = select i1 [[B:%.*]], i1 [[TMP1]], i1 false
+; CHECK-NEXT: [[TMP1:%.*]] = icmp ne i32 [[X:%.*]], [[Y:%.*]]
+; CHECK-NEXT: [[TMP2:%.*]] = select i1 [[TMP1]], i1 true, i1 [[A:%.*]]
+; CHECK-NEXT: [[R:%.*]] = select i1 [[B:%.*]], i1 [[TMP2]], i1 false
; CHECK-NEXT: ret i1 [[R]]
;
%c = icmp eq i32 %x, %y
@@ -665,9 +665,9 @@ define i1 @and_or3_multiuse(i1 %a, i1 %b, i32 %x, i32 %y) {
define <2 x i1> @and_or3_vec(<2 x i1> %a, <2 x i1> %b, <2 x i32> %x, <2 x i32> %y) {
; CHECK-LABEL: @and_or3_vec(
-; CHECK-NEXT: [[C:%.*]] = icmp ne <2 x i32> [[X:%.*]], [[Y:%.*]]
-; CHECK-NEXT: [[TMP1:%.*]] = select <2 x i1> [[C]], <2 x i1> <i1 true, i1 true>, <2 x i1> [[A:%.*]]
-; CHECK-NEXT: [[R:%.*]] = select <2 x i1> [[B:%.*]], <2 x i1> [[TMP1]], <2 x i1> zeroinitializer
+; CHECK-NEXT: [[TMP1:%.*]] = icmp ne <2 x i32> [[X:%.*]], [[Y:%.*]]
+; CHECK-NEXT: [[TMP2:%.*]] = select <2 x i1> [[TMP1]], <2 x i1> <i1 true, i1 true>, <2 x i1> [[A:%.*]]
+; CHECK-NEXT: [[R:%.*]] = select <2 x i1> [[B:%.*]], <2 x i1> [[TMP2]], <2 x i1> zeroinitializer
; CHECK-NEXT: ret <2 x i1> [[R]]
;
%c = icmp eq <2 x i32> %x, %y
@@ -678,9 +678,9 @@ define <2 x i1> @and_or3_vec(<2 x i1> %a, <2 x i1> %b, <2 x i32> %x, <2 x i32> %
define <2 x i1> @and_or3_vec_commuted(<2 x i1> %a, <2 x i1> %b, <2 x i32> %x, <2 x i32> %y) {
; CHECK-LABEL: @and_or3_vec_commuted(
-; CHECK-NEXT: [[C:%.*]] = icmp ne <2 x i32> [[X:%.*]], [[Y:%.*]]
-; CHECK-NEXT: [[TMP1:%.*]] = select <2 x i1> [[C]], <2 x i1> <i1 true, i1 true>, <2 x i1> [[A:%.*]]
-; CHECK-NEXT: [[R:%.*]] = select <2 x i1> [[B:%.*]], <2 x i1> [[TMP1]], <2 x i1> zeroinitializer
+; CHECK-NEXT: [[TMP1:%.*]] = icmp ne <2 x i32> [[X:%.*]], [[Y:%.*]]
+; CHECK-NEXT: [[TMP2:%.*]] = select <2 x i1> [[TMP1]], <2 x i1> <i1 true, i1 true>, <2 x i1> [[A:%.*]]
+; CHECK-NEXT: [[R:%.*]] = select <2 x i1> [[B:%.*]], <2 x i1> [[TMP2]], <2 x i1> zeroinitializer
; CHECK-NEXT: ret <2 x i1> [[R]]
;
%c = icmp eq <2 x i32> %x, %y
@@ -877,9 +877,9 @@ entry:
define i1 @or_and3(i1 %a, i1 %b, i32 %x, i32 %y) {
; CHECK-LABEL: @or_and3(
-; CHECK-NEXT: [[C:%.*]] = icmp ne i32 [[X:%.*]], [[Y:%.*]]
-; CHECK-NEXT: [[TMP1:%.*]] = select i1 [[C]], i1 [[B:%.*]], i1 false
-; CHECK-NEXT: [[R:%.*]] = select i1 [[A:%.*]], i1 true, i1 [[TMP1]]
+; CHECK-NEXT: [[TMP1:%.*]] = icmp ne i32 [[X:%.*]], [[Y:%.*]]
+; CHECK-NEXT: [[TMP2:%.*]] = select i1 [[TMP1]], i1 [[B:%.*]], i1 false
+; CHECK-NEXT: [[R:%.*]] = select i1 [[A:%.*]], i1 true, i1 [[TMP2]]
; CHECK-NEXT: ret i1 [[R]]
;
%c = icmp eq i32 %x, %y
@@ -890,9 +890,9 @@ define i1 @or_and3(i1 %a, i1 %b, i32 %x, i32 %y) {
define i1 @or_and3_commuted(i1 %a, i1 %b, i32 %x, i32 %y) {
; CHECK-LABEL: @or_and3_commuted(
-; CHECK-NEXT: [[C:%.*]] = icmp ne i32 [[X:%.*]], [[Y:%.*]]
-; CHECK-NEXT: [[TMP1:%.*]] = select i1 [[C]], i1 [[B:%.*]], i1 false
-; CHECK-NEXT: [[R:%.*]] = select i1 [[A:%.*]], i1 true, i1 [[TMP1]]
+; CHECK-NEXT: [[TMP1:%.*]] = icmp ne i32 [[X:%.*]], [[Y:%.*]]
+; CHECK-NEXT: [[TMP2:%.*]] = select i1 [[TMP1]], i1 [[B:%.*]], i1 false
+; CHECK-NEXT: [[R:%.*]] = select i1 [[A:%.*]], i1 true, i1 [[TMP2]]
; CHECK-NEXT: ret i1 [[R]]
;
%c = icmp eq i32 %x, %y
@@ -929,9 +929,9 @@ define i1 @or_and3_multiuse(i1 %a, i1 %b, i32 %x, i32 %y) {
define <2 x i1> @or_and3_vec(<2 x i1> %a, <2 x i1> %b, <2 x i32> %x, <2 x i32> %y) {
; CHECK-LABEL: @or_and3_vec(
-; CHECK-NEXT: [[C:%.*]] = icmp ne <2 x i32> [[X:%.*]], [[Y:%.*]]
-; CHECK-NEXT: [[TMP1:%.*]] = select <2 x i1> [[C]], <2 x i1> [[B:%.*]], <2 x i1> zeroinitializer
-; CHECK-NEXT: [[R:%.*]] = select <2 x i1> [[A:%.*]], <2 x i1> <i1 true, i1 true>, <2 x i1> [[TMP1]]
+; CHECK-NEXT: [[TMP1:%.*]] = icmp ne <2 x i32> [[X:%.*]], [[Y:%.*]]
+; CHECK-NEXT: [[TMP2:%.*]] = select <2 x i1> [[TMP1]], <2 x i1> [[B:%.*]], <2 x i1> zeroinitializer
+; CHECK-NEXT: [[R:%.*]] = select <2 x i1> [[A:%.*]], <2 x i1> <i1 true, i1 true>, <2 x i1> [[TMP2]]
; CHECK-NEXT: ret <2 x i1> [[R]]
;
%c = icmp eq <2 x i32> %x, %y
@@ -942,9 +942,9 @@ define <2 x i1> @or_and3_vec(<2 x i1> %a, <2 x i1> %b, <2 x i32> %x, <2 x i32> %
define <2 x i1> @or_and3_vec_commuted(<2 x i1> %a, <2 x i1> %b, <2 x i32> %x, <2 x i32> %y) {
; CHECK-LABEL: @or_and3_vec_commuted(
-; CHECK-NEXT: [[C:%.*]] = icmp ne <2 x i32> [[X:%.*]], [[Y:%.*]]
-; CHECK-NEXT: [[TMP1:%.*]] = select <2 x i1> [[C]], <2 x i1> [[B:%.*]], <2 x i1> zeroinitializer
-; CHECK-NEXT: [[R:%.*]] = select <2 x i1> [[A:%.*]], <2 x i1> <i1 true, i1 true>, <2 x i1> [[TMP1]]
+; CHECK-NEXT: [[TMP1:%.*]] = icmp ne <2 x i32> [[X:%.*]], [[Y:%.*]]
+; CHECK-NEXT: [[TMP2:%.*]] = select <2 x i1> [[TMP1]], <2 x i1> [[B:%.*]], <2 x i1> zeroinitializer
+; CHECK-NEXT: [[R:%.*]] = select <2 x i1> [[A:%.*]], <2 x i1> <i1 true, i1 true>, <2 x i1> [[TMP2]]
; CHECK-NEXT: ret <2 x i1> [[R]]
;
%c = icmp eq <2 x i32> %x, %y
@@ -968,9 +968,8 @@ define i1 @or_and3_wrong_operand(i1 %a, i1 %b, i32 %x, i32 %y, i1 %d) {
define i8 @test_or_umax(i8 %x, i8 %y, i1 %cond) {
; CHECK-LABEL: @test_or_umax(
-; CHECK-NEXT: [[CMP:%.*]] = icmp ugt i8 [[X:%.*]], [[Y:%.*]]
-; CHECK-NEXT: [[OR:%.*]] = select i1 [[COND:%.*]], i1 true, i1 [[CMP]]
-; CHECK-NEXT: [[RET:%.*]] = select i1 [[OR]], i8 [[X]], i8 [[Y]]
+; CHECK-NEXT: [[TMP1:%.*]] = call i8 @llvm.umax.i8(i8 [[X:%.*]], i8 [[Y:%.*]])
+; CHECK-NEXT: [[RET:%.*]] = select i1 [[COND:%.*]], i8 [[X]], i8 [[TMP1]]
; CHECK-NEXT: ret i8 [[RET]]
;
%cmp = icmp ugt i8 %x, %y
@@ -981,9 +980,8 @@ define i8 @test_or_umax(i8 %x, i8 %y, i1 %cond) {
define i8 @test_or_umin(i8 %x, i8 %y, i1 %cond) {
; CHECK-LABEL: @test_or_umin(
-; CHECK-NEXT: [[CMP:%.*]] = icmp ugt i8 [[X:%.*]], [[Y:%.*]]
-; CHECK-NEXT: [[OR:%.*]] = select i1 [[COND:%.*]], i1 true, i1 [[CMP]]
-; CHECK-NEXT: [[RET:%.*]] = select i1 [[OR]], i8 [[Y]], i8 [[X]]
+; CHECK-NEXT: [[TMP1:%.*]] = call i8 @llvm.umin.i8(i8 [[X:%.*]], i8 [[Y:%.*]])
+; CHECK-NEXT: [[RET:%.*]] = select i1 [[COND:%.*]], i8 [[Y]], i8 [[TMP1]]
; CHECK-NEXT: ret i8 [[RET]]
;
%cmp = icmp ugt i8 %x, %y
@@ -994,9 +992,8 @@ define i8 @test_or_umin(i8 %x, i8 %y, i1 %cond) {
define i8 @test_and_umax(i8 %x, i8 %y, i1 %cond) {
; CHECK-LABEL: @test_and_umax(
-; CHECK-NEXT: [[CMP:%.*]] = icmp ugt i8 [[X:%.*]], [[Y:%.*]]
-; CHECK-NEXT: [[AND:%.*]] = select i1 [[COND:%.*]], i1 [[CMP]], i1 false
-; CHECK-NEXT: [[RET:%.*]] = select i1 [[AND]], i8 [[X]], i8 [[Y]]
+; CHECK-NEXT: [[TMP1:%.*]] = call i8 @llvm.umax.i8(i8 [[X:%.*]], i8 [[Y:%.*]])
+; CHECK-NEXT: [[RET:%.*]] = select i1 [[COND:%.*]], i8 [[TMP1]], i8 [[Y]]
; CHECK-NEXT: ret i8 [[RET]]
;
%cmp = icmp ugt i8 %x, %y
@@ -1007,9 +1004,8 @@ define i8 @test_and_umax(i8 %x, i8 %y, i1 %cond) {
define i8 @test_and_umin(i8 %x, i8 %y, i1 %cond) {
; CHECK-LABEL: @test_and_umin(
-; CHECK-NEXT: [[CMP:%.*]] = icmp ugt i8 [[X:%.*]], [[Y:%.*]]
-; CHECK-NEXT: [[AND:%.*]] = select i1 [[COND:%.*]], i1 [[CMP]], i1 false
-; CHECK-NEXT: [[RET:%.*]] = select i1 [[AND]], i8 [[Y]], i8 [[X]]
+; CHECK-NEXT: [[TMP1:%.*]] = call i8 @llvm.umin.i8(i8 [[X:%.*]], i8 [[Y:%.*]])
+; CHECK-NEXT: [[RET:%.*]] = select i1 [[COND:%.*]], i8 [[TMP1]], i8 [[X]]
; CHECK-NEXT: ret i8 [[RET]]
;
%cmp = icmp ugt i8 %x, %y
@@ -1021,9 +1017,8 @@ define i8 @test_and_umin(i8 %x, i8 %y, i1 %cond) {
define i8 @test_or_umax_bitwise1(i8 %x, i8 %y, i8 %val) {
; CHECK-LABEL: @test_or_umax_bitwise1(
; CHECK-NEXT: [[COND:%.*]] = icmp eq i8 [[VAL:%.*]], 0
-; CHECK-NEXT: [[CMP:%.*]] = icmp ugt i8 [[X:%.*]], [[Y:%.*]]
-; CHECK-NEXT: [[OR:%.*]] = or i1 [[COND]], [[CMP]]
-; CHECK-NEXT: [[RET:%.*]] = select i1 [[OR]], i8 [[X]], i8 [[Y]]
+; CHECK-NEXT: [[TMP1:%.*]] = call i8 @llvm.umax.i8(i8 [[X:%.*]], i8 [[Y:%.*]])
+; CHECK-NEXT: [[RET:%.*]] = select i1 [[COND]], i8 [[X]], i8 [[TMP1]]
; CHECK-NEXT: ret i8 [[RET]]
;
%cond = icmp eq i8 %val, 0 ; thwart complexity-based ordering
@@ -1036,9 +1031,8 @@ define i8 @test_or_umax_bitwise1(i8 %x, i8 %y, i8 %val) {
define i8 @test_or_umax_bitwise2(i8 %x, i8 %y, i8 %val) {
; CHECK-LABEL: @test_or_umax_bitwise2(
; CHECK-NEXT: [[COND:%.*]] = icmp eq i8 [[VAL:%.*]], 0
-; CHECK-NEXT: [[CMP:%.*]] = icmp ugt i8 [[X:%.*]], [[Y:%.*]]
-; CHECK-NEXT: [[OR:%.*]] = or i1 [[CMP]], [[COND]]
-; CHECK-NEXT: [[RET:%.*]] = select i1 [[OR]], i8 [[X]], i8 [[Y]]
+; CHECK-NEXT: [[TMP1:%.*]] = call i8 @llvm.umax.i8(i8 [[X:%.*]], i8 [[Y:%.*]])
+; CHECK-NEXT: [[RET:%.*]] = select i1 [[COND]], i8 [[X]], i8 [[TMP1]]
; CHECK-NEXT: ret i8 [[RET]]
;
%cond = icmp eq i8 %val, 0 ; thwart complexity-based ordering
@@ -1051,9 +1045,8 @@ define i8 @test_or_umax_bitwise2(i8 %x, i8 %y, i8 %val) {
define i8 @test_and_umax_bitwise1(i8 %x, i8 %y, i8 %val) {
; CHECK-LABEL: @test_and_umax_bitwise1(
; CHECK-NEXT: [[COND:%.*]] = icmp eq i8 [[VAL:%.*]], 0
-; CHECK-NEXT: [[CMP:%.*]] = icmp ugt i8 [[X:%.*]], [[Y:%.*]]
-; CHECK-NEXT: [[AND:%.*]] = and i1 [[COND]], [[CMP]]
-; CHECK-NEXT: [[RET:%.*]] = select i1 [[AND]], i8 [[X]], i8 [[Y]]
+; CHECK-NEXT: [[TMP1:%.*]] = call i8 @llvm.umax.i8(i8 [[X:%.*]], i8 [[Y:%.*]])
+; CHECK-NEXT: [[RET:%.*]] = select i1 [[COND]], i8 [[TMP1]], i8 [[Y]]
; CHECK-NEXT: ret i8 [[RET]]
;
%cond = icmp eq i8 %val, 0 ; thwart complexity-based ordering
@@ -1066,9 +1059,8 @@ define i8 @test_and_umax_bitwise1(i8 %x, i8 %y, i8 %val) {
define i8 @test_and_umax_bitwise2(i8 %x, i8 %y, i8 %val) {
; CHECK-LABEL: @test_and_umax_bitwise2(
; CHECK-NEXT: [[COND:%.*]] = icmp eq i8 [[VAL:%.*]], 0
-; CHECK-NEXT: [[CMP:%.*]] = icmp ugt i8 [[X:%.*]], [[Y:%.*]]
-; CHECK-NEXT: [[AND:%.*]] = and i1 [[CMP]], [[COND]]
-; CHECK-NEXT: [[RET:%.*]] = select i1 [[AND]], i8 [[X]], i8 [[Y]]
+; CHECK-NEXT: [[TMP1:%.*]] = call i8 @llvm.umax.i8(i8 [[X:%.*]], i8 [[Y:%.*]])
+; CHECK-NEXT: [[RET:%.*]] = select i1 [[COND]], i8 [[TMP1]], i8 [[Y]]
; CHECK-NEXT: ret i8 [[RET]]
;
%cond = icmp eq i8 %val, 0 ; thwart complexity-based ordering
@@ -1082,9 +1074,8 @@ define i8 @test_and_umax_bitwise2(i8 %x, i8 %y, i8 %val) {
define i8 @test_or_smax(i8 %x, i8 %y, i1 %cond) {
; CHECK-LABEL: @test_or_smax(
-; CHECK-NEXT: [[CMP:%.*]] = icmp sgt i8 [[X:%.*]], [[Y:%.*]]
-; CHECK-NEXT: [[OR:%.*]] = select i1 [[COND:%.*]], i1 true, i1 [[CMP]]
-; CHECK-NEXT: [[RET:%.*]] = select i1 [[OR]], i8 [[X]], i8 [[Y]]
+; CHECK-NEXT: [[TMP1:%.*]] = call i8 @llvm.smax.i8(i8 [[X:%.*]], i8 [[Y:%.*]])
+; CHECK-NEXT: [[RET:%.*]] = select i1 [[COND:%.*]], i8 [[X]], i8 [[TMP1]]
; CHECK-NEXT: ret i8 [[RET]]
;
%cmp = icmp sgt i8 %x, %y
@@ -1095,10 +1086,8 @@ define i8 @test_or_smax(i8 %x, i8 %y, i1 %cond) {
define i8 @test_or_abs(i8 %x, i1 %cond) {
; CHECK-LABEL: @test_or_abs(
-; CHECK-NEXT: [[CMP:%.*]] = icmp sgt i8 [[X:%.*]], -1
-; CHECK-NEXT: [[NEG:%.*]] = sub nsw i8 0, [[X]]
-; CHECK-NEXT: [[OR:%.*]] = select i1 [[COND:%.*]], i1 true, i1 [[CMP]]
-; CHECK-NEXT: [[RET:%.*]] = select i1 [[OR]], i8 [[X]], i8 [[NEG]]
+; CHECK-NEXT: [[TMP1:%.*]] = call i8 @llvm.abs.i8(i8 [[X:%.*]], i1 true)
+; CHECK-NEXT: [[RET:%.*]] = select i1 [[COND:%.*]], i8 [[X]], i8 [[TMP1]]
; CHECK-NEXT: ret i8 [[RET]]
;
%cmp = icmp sgt i8 %x, -1
@@ -1169,9 +1158,7 @@ define i8 @test_or_umax_multiuse_cond(i8 %x, i8 %y, i1 %cond) {
define i8 @test_or_eq_a_b(i1 %other_cond, i8 %a, i8 %b) {
; CHECK-LABEL: @test_or_eq_a_b(
-; CHECK-NEXT: [[CMP:%.*]] = icmp eq i8 [[A:%.*]], [[B:%.*]]
-; CHECK-NEXT: [[COND:%.*]] = or i1 [[CMP]], [[OTHER_COND:%.*]]
-; CHECK-NEXT: [[SELECT:%.*]] = select i1 [[COND]], i8 [[A]], i8 [[B]]
+; CHECK-NEXT: [[SELECT:%.*]] = select i1 [[OTHER_COND:%.*]], i8 [[A:%.*]], i8 [[B:%.*]]
; CHECK-NEXT: ret i8 [[SELECT]]
;
%cmp = icmp eq i8 %a, %b
@@ -1182,9 +1169,7 @@ define i8 @test_or_eq_a_b(i1 %other_cond, i8 %a, i8 %b) {
define i8 @test_and_ne_a_b(i1 %other_cond, i8 %a, i8 %b) {
; CHECK-LABEL: @test_and_ne_a_b(
-; CHECK-NEXT: [[CMP:%.*]] = icmp ne i8 [[A:%.*]], [[B:%.*]]
-; CHECK-NEXT: [[COND:%.*]] = and i1 [[CMP]], [[OTHER_COND:%.*]]
-; CHECK-NEXT: [[SELECT:%.*]] = select i1 [[COND]], i8 [[A]], i8 [[B]]
+; CHECK-NEXT: [[SELECT:%.*]] = select i1 [[OTHER_COND:%.*]], i8 [[A:%.*]], i8 [[B:%.*]]
; CHECK-NEXT: ret i8 [[SELECT]]
;
%cmp = icmp ne i8 %a, %b
@@ -1195,9 +1180,7 @@ define i8 @test_and_ne_a_b(i1 %other_cond, i8 %a, i8 %b) {
define i8 @test_or_eq_a_b_commuted(i1 %other_cond, i8 %a, i8 %b) {
; CHECK-LABEL: @test_or_eq_a_b_commuted(
-; CHECK-NEXT: [[CMP:%.*]] = icmp eq i8 [[A:%.*]], [[B:%.*]]
-; CHECK-NEXT: [[COND:%.*]] = or i1 [[CMP]], [[OTHER_COND:%.*]]
-; CHECK-NEXT: [[SELECT:%.*]] = select i1 [[COND]], i8 [[B]], i8 [[A]]
+; CHECK-NEXT: [[SELECT:%.*]] = select i1 [[OTHER_COND:%.*]], i8 [[B:%.*]], i8 [[A:%.*]]
; CHECK-NEXT: ret i8 [[SELECT]]
;
%cmp = icmp eq i8 %a, %b
@@ -1208,9 +1191,7 @@ define i8 @test_or_eq_a_b_commuted(i1 %other_cond, i8 %a, i8 %b) {
define i8 @test_and_ne_a_b_commuted(i1 %other_cond, i8 %a, i8 %b) {
; CHECK-LABEL: @test_and_ne_a_b_commuted(
-; CHECK-NEXT: [[CMP:%.*]] = icmp ne i8 [[A:%.*]], [[B:%.*]]
-; CHECK-NEXT: [[COND:%.*]] = and i1 [[CMP]], [[OTHER_COND:%.*]]
-; CHECK-NEXT: [[SELECT:%.*]] = select i1 [[COND]], i8 [[B]], i8 [[A]]
+; CHECK-NEXT: [[SELECT:%.*]] = select i1 [[OTHER_COND:%.*]], i8 [[B:%.*]], i8 [[A:%.*]]
; CHECK-NEXT: ret i8 [[SELECT]]
;
%cmp = icmp ne i8 %a, %b
@@ -1222,9 +1203,7 @@ define i8 @test_and_ne_a_b_commuted(i1 %other_cond, i8 %a, i8 %b) {
define i8 @test_or_eq_different_operands(i8 %a, i8 %b, i8 %c) {
; CHECK-LABEL: @test_or_eq_different_operands(
; CHECK-NEXT: [[CMP:%.*]] = icmp eq i8 [[A:%.*]], [[C:%.*]]
-; CHECK-NEXT: [[CMP1:%.*]] = icmp eq i8 [[B:%.*]], [[A]]
-; CHECK-NEXT: [[COND:%.*]] = or i1 [[CMP]], [[CMP1]]
-; CHECK-NEXT: [[SELECT:%.*]] = select i1 [[COND]], i8 [[A]], i8 [[B]]
+; CHECK-NEXT: [[SELECT:%.*]] = select i1 [[CMP]], i8 [[A]], i8 [[B:%.*]]
; CHECK-NEXT: ret i8 [[SELECT]]
;
%cmp = icmp eq i8 %a, %c
@@ -1240,7 +1219,7 @@ define i8 @test_or_eq_a_b_multi_use(i1 %other_cond, i8 %a, i8 %b) {
; CHECK-NEXT: [[COND:%.*]] = or i1 [[CMP]], [[OTHER_COND:%.*]]
; CHECK-NEXT: call void @use(i1 [[CMP]])
; CHECK-NEXT: call void @use(i1 [[COND]])
-; CHECK-NEXT: [[SELECT:%.*]] = select i1 [[COND]], i8 [[A]], i8 [[B]]
+; CHECK-NEXT: [[SELECT:%.*]] = select i1 [[OTHER_COND]], i8 [[A]], i8 [[B]]
; CHECK-NEXT: ret i8 [[SELECT]]
;
%cmp = icmp eq i8 %a, %b
@@ -1253,9 +1232,7 @@ define i8 @test_or_eq_a_b_multi_use(i1 %other_cond, i8 %a, i8 %b) {
define <2 x i8> @test_or_eq_a_b_vec(<2 x i1> %other_cond, <2 x i8> %a, <2 x i8> %b) {
; CHECK-LABEL: @test_or_eq_a_b_vec(
-; CHECK-NEXT: [[CMP:%.*]] = icmp eq <2 x i8> [[A:%.*]], [[B:%.*]]
-; CHECK-NEXT: [[COND:%.*]] = or <2 x i1> [[CMP]], [[OTHER_COND:%.*]]
-; CHECK-NEXT: [[SELECT:%.*]] = select <2 x i1> [[COND]], <2 x i8> [[A]], <2 x i8> [[B]]
+; CHECK-NEXT: [[SELECT:%.*]] = select <2 x i1> [[OTHER_COND:%.*]], <2 x i8> [[A:%.*]], <2 x i8> [[B:%.*]]
; CHECK-NEXT: ret <2 x i8> [[SELECT]]
;
%cmp = icmp eq <2 x i8> %a, %b
@@ -1266,10 +1243,7 @@ define <2 x i8> @test_or_eq_a_b_vec(<2 x i1> %other_cond, <2 x i8> %a, <2 x i8>
define i8 @test_or_ne_a_b(i1 %other_cond, i8 %a, i8 %b) {
; CHECK-LABEL: @test_or_ne_a_b(
-; CHECK-NEXT: [[CMP:%.*]] = icmp ne i8 [[A:%.*]], [[B:%.*]]
-; CHECK-NEXT: [[COND:%.*]] = or i1 [[CMP]], [[OTHER_COND:%.*]]
-; CHECK-NEXT: [[SELECT:%.*]] = select i1 [[COND]], i8 [[A]], i8 [[B]]
-; CHECK-NEXT: ret i8 [[SELECT]]
+; CHECK-NEXT: ret i8 [[A:%.*]]
;
%cmp = icmp ne i8 %a, %b
%cond = or i1 %other_cond, %cmp
@@ -1294,9 +1268,7 @@ define i8 @test_and_ne_different_operands_fail(i8 %a, i8 %b, i8 %c) {
define i8 @test_logical_or_eq_a_b(i1 %other_cond, i8 %a, i8 %b) {
; CHECK-LABEL: @test_logical_or_eq_a_b(
-; CHECK-NEXT: [[CMP:%.*]] = icmp eq i8 [[A:%.*]], [[B:%.*]]
-; CHECK-NEXT: [[OR_COND:%.*]] = select i1 [[OTHER_COND:%.*]], i1 true, i1 [[CMP]]
-; CHECK-NEXT: [[SELECT:%.*]] = select i1 [[OR_COND]], i8 [[A]], i8 [[B]]
+; CHECK-NEXT: [[SELECT:%.*]] = select i1 [[OTHER_COND:%.*]], i8 [[A:%.*]], i8 [[B:%.*]]
; CHECK-NEXT: ret i8 [[SELECT]]
;
%cmp = icmp eq i8 %a, %b
@@ -1320,9 +1292,7 @@ define i8 @test_logical_commuted_or_eq_a_b(i1 %other_cond, i8 %a, i8 %b) {
define i8 @test_logical_and_ne_a_b(i1 %other_cond, i8 %a, i8 %b) {
; CHECK-LABEL: @test_logical_and_ne_a_b(
-; CHECK-NEXT: [[CMP:%.*]] = icmp ne i8 [[A:%.*]], [[B:%.*]]
-; CHECK-NEXT: [[OR_COND:%.*]] = select i1 [[OTHER_COND:%.*]], i1 [[CMP]], i1 false
-; CHECK-NEXT: [[SELECT:%.*]] = select i1 [[OR_COND]], i8 [[A]], i8 [[B]]
+; CHECK-NEXT: [[SELECT:%.*]] = select i1 [[OTHER_COND:%.*]], i8 [[A:%.*]], i8 [[B:%.*]]
; CHECK-NEXT: ret i8 [[SELECT]]
;
%cmp = icmp ne i8 %a, %b
diff --git a/llvm/test/Transforms/InstCombine/select-factorize.ll b/llvm/test/Transforms/InstCombine/select-factorize.ll
index 1b727a3aaee337..386c8e522759e2 100644
--- a/llvm/test/Transforms/InstCombine/select-factorize.ll
+++ b/llvm/test/Transforms/InstCombine/select-factorize.ll
@@ -303,7 +303,7 @@ define i1 @and_logic_and_logic_or_not_one_use(i1 %c, i1 %a, i1 %b) {
; CHECK-LABEL: @and_logic_and_logic_or_not_one_use(
; CHECK-NEXT: [[AC:%.*]] = and i1 [[A:%.*]], [[C:%.*]]
; CHECK-NEXT: [[BC:%.*]] = select i1 [[B:%.*]], i1 [[C]], i1 false
-; CHECK-NEXT: [[OR:%.*]] = select i1 [[BC]], i1 true, i1 [[AC]]
+; CHECK-NEXT: [[OR:%.*]] = select i1 [[B]], i1 [[C]], i1 [[AC]]
; CHECK-NEXT: call void @use(i1 [[AC]])
; CHECK-NEXT: call void @use(i1 [[BC]])
; CHECK-NEXT: ret i1 [[OR]]
@@ -368,7 +368,7 @@ define i1 @and_and_logic_or_not_one_use(i1 %c, i1 %a, i1 %b) {
; CHECK-LABEL: @and_and_logic_or_not_one_use(
; CHECK-NEXT: [[AC:%.*]] = and i1 [[A:%.*]], [[C:%.*]]
; CHECK-NEXT: [[BC:%.*]] = and i1 [[C]], [[B:%.*]]
-; CHECK-NEXT: [[OR:%.*]] = select i1 [[BC]], i1 true, i1 [[AC]]
+; CHECK-NEXT: [[OR:%.*]] = select i1 [[B]], i1 [[C]], i1 [[AC]]
; CHECK-NEXT: call void @use(i1 [[AC]])
; CHECK-NEXT: call void @use(i1 [[BC]])
; CHECK-NEXT: ret i1 [[OR]]
@@ -532,7 +532,7 @@ define i1 @logic_or_logic_and_not_one_use(i1 %c, i1 %a, i1 %b) {
; CHECK-LABEL: @logic_or_logic_and_not_one_use(
; CHECK-NEXT: [[AC:%.*]] = select i1 [[C:%.*]], i1 true, i1 [[A:%.*]]
; CHECK-NEXT: [[BC:%.*]] = select i1 [[B:%.*]], i1 true, i1 [[C]]
-; CHECK-NEXT: [[OR:%.*]] = select i1 [[BC]], i1 [[AC]], i1 false
+; CHECK-NEXT: [[OR:%.*]] = select i1 [[B]], i1 [[AC]], i1 [[C]]
; CHECK-NEXT: call void @use(i1 [[AC]])
; CHECK-NEXT: call void @use(i1 [[BC]])
; CHECK-NEXT: ret i1 [[OR]]
@@ -681,7 +681,7 @@ define i1 @or_logic_or_logic_and_not_one_use(i1 %c, i1 %a, i1 %b) {
; CHECK-LABEL: @or_logic_or_logic_and_not_one_use(
; CHECK-NEXT: [[AC:%.*]] = or i1 [[C:%.*]], [[A:%.*]]
; CHECK-NEXT: [[BC:%.*]] = select i1 [[B:%.*]], i1 true, i1 [[C]]
-; CHECK-NEXT: [[OR:%.*]] = select i1 [[BC]], i1 [[AC]], i1 false
+; CHECK-NEXT: [[OR:%.*]] = select i1 [[B]], i1 [[AC]], i1 [[C]]
; CHECK-NEXT: call void @use(i1 [[AC]])
; CHECK-NEXT: call void @use(i1 [[BC]])
; CHECK-NEXT: ret i1 [[OR]]
@@ -746,7 +746,7 @@ define i1 @or_or_logic_and_not_one_use(i1 %c, i1 %a, i1 %b) {
; CHECK-LABEL: @or_or_logic_and_not_one_use(
; CHECK-NEXT: [[AC:%.*]] = or i1 [[C:%.*]], [[A:%.*]]
; CHECK-NEXT: [[BC:%.*]] = or i1 [[B:%.*]], [[C]]
-; CHECK-NEXT: [[OR:%.*]] = select i1 [[BC]], i1 [[AC]], i1 false
+; CHECK-NEXT: [[OR:%.*]] = select i1 [[B]], i1 [[AC]], i1 [[C]]
; CHECK-NEXT: call void @use(i1 [[AC]])
; CHECK-NEXT: call void @use(i1 [[BC]])
; CHECK-NEXT: ret i1 [[OR]]
diff --git a/llvm/test/Transforms/InstCombine/zext-or-icmp.ll b/llvm/test/Transforms/InstCombine/zext-or-icmp.ll
index 585f099fd41b1c..661c36038a67ea 100644
--- a/llvm/test/Transforms/InstCombine/zext-or-icmp.ll
+++ b/llvm/test/Transforms/InstCombine/zext-or-icmp.ll
@@ -170,18 +170,16 @@ define i32 @PR49475(i32 %x, i16 %y) {
define i8 @PR49475_infloop(i32 %t0, i16 %insert, i64 %e, i8 %i162) {
; CHECK-LABEL: @PR49475_infloop(
-; CHECK-NEXT: [[B:%.*]] = icmp eq i32 [[T0:%.*]], 0
; CHECK-NEXT: [[B2:%.*]] = icmp eq i16 [[INSERT:%.*]], 0
-; CHECK-NEXT: [[T1:%.*]] = or i1 [[B]], [[B2]]
-; CHECK-NEXT: [[TMP1:%.*]] = and i32 [[T0]], 1
+; CHECK-NEXT: [[TMP1:%.*]] = and i32 [[T0:%.*]], 1
; CHECK-NEXT: [[TMP2:%.*]] = or disjoint i32 [[TMP1]], 140
; CHECK-NEXT: [[TMP3:%.*]] = zext nneg i32 [[TMP2]] to i64
-; CHECK-NEXT: [[XOR1:%.*]] = select i1 [[T1]], i64 [[TMP3]], i64 140
+; CHECK-NEXT: [[XOR:%.*]] = select i1 [[B2]], i64 [[TMP3]], i64 140
; CHECK-NEXT: [[CONV16:%.*]] = sext i8 [[I162:%.*]] to i64
; CHECK-NEXT: [[SUB17:%.*]] = sub i64 [[CONV16]], [[E:%.*]]
; CHECK-NEXT: [[SEXT:%.*]] = shl i64 [[SUB17]], 32
; CHECK-NEXT: [[CONV18:%.*]] = ashr exact i64 [[SEXT]], 32
-; CHECK-NEXT: [[CMP:%.*]] = icmp sge i64 [[XOR1]], [[CONV18]]
+; CHECK-NEXT: [[CMP:%.*]] = icmp sge i64 [[XOR]], [[CONV18]]
; CHECK-NEXT: [[CONV19:%.*]] = zext i1 [[CMP]] to i16
; CHECK-NEXT: [[OR21:%.*]] = or i16 [[CONV19]], [[INSERT]]
; CHECK-NEXT: [[TOBOOL23_NOT:%.*]] = icmp eq i16 [[OR21]], 0
diff --git a/llvm/test/Transforms/Reassociate/basictest.ll b/llvm/test/Transforms/Reassociate/basictest.ll
index 6205256a31048a..3f4057dd14e7e1 100644
--- a/llvm/test/Transforms/Reassociate/basictest.ll
+++ b/llvm/test/Transforms/Reassociate/basictest.ll
@@ -239,10 +239,8 @@ define i32 @test14(i32 %X1, i32 %X2) {
define i32 @test15(i32 %X1, i32 %X2, i32 %X3) {
; CHECK-LABEL: @test15(
-; CHECK-NEXT: [[A:%.*]] = icmp ne i32 [[X1:%.*]], 0
; CHECK-NEXT: [[B:%.*]] = icmp slt i32 [[X2:%.*]], [[X3:%.*]]
-; CHECK-NEXT: [[C:%.*]] = and i1 [[A]], [[B]]
-; CHECK-NEXT: [[D:%.*]] = select i1 [[C]], i32 [[X1]], i32 0
+; CHECK-NEXT: [[D:%.*]] = select i1 [[B]], i32 [[X1:%.*]], i32 0
; CHECK-NEXT: ret i32 [[D]]
;
%A = icmp ne i32 %X1, 0
More information about the llvm-commits
mailing list