[PATCH] D25969: [AliasSetTracker] Make AST smarter about intrinsics that don't actually affect memory.

Chad Rosier via llvm-commits llvm-commits at lists.llvm.org
Tue Oct 25 14:56:49 PDT 2016


mcrosier created this revision.
mcrosier added reviewers: dberlin, mkuper, gberry.
mcrosier added a subscriber: llvm-commits.

AFAICT, this is the same approach taken in MemorySSA.

PTAL,
Chad


https://reviews.llvm.org/D25969

Files:
  lib/Analysis/AliasSetTracker.cpp
  test/Analysis/AliasSet/intrinsics.ll


Index: test/Analysis/AliasSet/intrinsics.ll
===================================================================
--- /dev/null
+++ test/Analysis/AliasSet/intrinsics.ll
@@ -0,0 +1,54 @@
+; RUN: opt -basicaa -print-alias-sets -S -o - < %s 2>&1 | FileCheck %s
+
+; CHECK: Alias sets for function 'test1':
+; CHECK: Alias Set Tracker: 2 alias sets for 2 pointer values.
+; CHECK:   AliasSet[0x{{[0-9a-f]+}}, 1] must alias, Mod       Pointers: (i8* %a, 1)
+; CHECK-NOT: 1 Unknown instruction
+; CHECK:   AliasSet[0x{{[0-9a-f]+}}, 1] must alias, Mod       Pointers: (i8* %b, 1)
+define void @test1(i32 %c) {
+entry:
+  %a = alloca i8, align 1
+  %b = alloca i8, align 1
+  store i8 1, i8* %a, align 1
+  %cond1 = icmp ne i32 %c, 0
+  call void @llvm.assume(i1 %cond1)
+  store i8 1, i8* %b, align 1
+  ret void
+}
+
+; CHECK: Alias sets for function 'test2':
+; CHECK: Alias Set Tracker: 2 alias sets for 2 pointer values.
+; CHECK:   AliasSet[0x{{[0-9a-f]+}}, 1] must alias, Mod       Pointers: (i8* %a, 1)
+; CHECK-NOT:  2 Unknown instructions
+; CHECK:   AliasSet[0x{{[0-9a-f]+}}, 1] must alias, Mod       Pointers: (i8* %b, 1)
+; CHECK-NOT:  2 Unknown instructions
+define void @test2(i8* %ptr) {
+entry:
+  %a = alloca i8, align 1
+  call void @llvm.lifetime.start(i64 1, i8* %a)
+  %b = alloca i8, align 1
+  call void @llvm.lifetime.start(i64 1, i8* %b)
+  store i8 1, i8* %a, align 1
+  call void @llvm.lifetime.end(i64 1, i8* %a)
+  store i8 1, i8* %b, align 1
+  call void @llvm.lifetime.end(i64 1, i8* %b)
+  ret void
+}
+
+; CHECK: Alias sets for function 'test3':
+; CHECK: Alias Set Tracker: 1 alias sets for 1 pointer values.
+; CHECK:   AliasSet[0x{{[0-9a-f]+}}, 1] must alias, Mod       Pointers: (i8* %ptr, 1)
+; CHECK-NOT:  2 Unknown instructions
+define void @test3(i8* %ptr) {
+  store i8 5, i8* %ptr
+  %i = call {}* @llvm.invariant.start.p0i8(i64 1, i8* %ptr)
+  call void @llvm.invariant.end.p0i8({}* %i, i64 1, i8* %ptr)
+  store i8 6, i8* %ptr
+  ret void
+}
+
+declare void @llvm.assume(i1)
+declare void @llvm.lifetime.start(i64, i8* nocapture)
+declare void @llvm.lifetime.end(i64, i8* nocapture)
+declare {}* @llvm.invariant.start.p0i8(i64, i8* nocapture) nounwind readonly
+declare void @llvm.invariant.end.p0i8({}*, i64, i8* nocapture) nounwind
Index: lib/Analysis/AliasSetTracker.cpp
===================================================================
--- lib/Analysis/AliasSetTracker.cpp
+++ lib/Analysis/AliasSetTracker.cpp
@@ -413,6 +413,21 @@
 void AliasSetTracker::addUnknown(Instruction *Inst) {
   if (isa<DbgInfoIntrinsic>(Inst))
     return; // Ignore DbgInfo Intrinsics.
+
+  if (const IntrinsicInst *II = dyn_cast<IntrinsicInst>(Inst)) {
+    // These intrinsics will show up as affecting memory, but they are just
+    // markers.
+    switch (II->getIntrinsicID()) {
+    default:
+      break;
+    case Intrinsic::lifetime_start:
+    case Intrinsic::lifetime_end:
+    case Intrinsic::invariant_start:
+    case Intrinsic::invariant_end:
+    case Intrinsic::assume:
+      return;
+    }
+  }
   if (!Inst->mayReadOrWriteMemory())
     return; // doesn't alias anything
 


-------------- next part --------------
A non-text attachment was scrubbed...
Name: D25969.75800.patch
Type: text/x-patch
Size: 3115 bytes
Desc: not available
URL: <http://lists.llvm.org/pipermail/llvm-commits/attachments/20161025/4b8baa36/attachment.bin>


More information about the llvm-commits mailing list