[PATCH] D115545: [Inline] Attempt to delete any discardable if unused functions

[Arthur Eubanks via Phabricator via llvm-commits]

aeubanks reopened this revision.
aeubanks added a comment.
This revision is now accepted and ready to land.

reduced repro

  $ opt -passes=inline -o /dev/null -S a.ll
  $ cat /tmp/a.ll
  %a = type { i8*, i8* }
  
  $f3 = comdat any
  
  define linkonce_odr void @f1() {
    %call5 = call void (i64, %a*)* @f2(void (i64, %a*)* @f3)
    ret void
  }
  
  define linkonce_odr void (i64, %a*)* @f2(void (i64, %a*)* %__f) {
    call void @llvm.dbg.value(metadata void (i64, %a*)* %__f, metadata !2, metadata !DIExpression()), !dbg !10
    call void %__f(i64 0, %a* null)
    ret void (i64, %a*)* null
  }
  
  define linkonce_odr void @f3(i64 %t.coerce0, %a* %t.coerce1) comdat {
    ret void
  }
  
  ; Function Attrs: nofree nosync nounwind readnone speculatable willreturn
  declare void @llvm.dbg.value(metadata, metadata, metadata) #0
  
  attributes #0 = { nofree nosync nounwind readnone speculatable willreturn }
  
  !llvm.module.flags = !{!0, !1}
  
  !0 = !{i32 7, !"Dwarf Version", i32 4}
  !1 = !{i32 2, !"Debug Info Version", i32 3}
  !2 = !DILocalVariable(name: "__f", arg: 3, scope: !3, file: !4, line: 3814, type: !9)
  !3 = distinct !DISubprogram(scope: !5, file: !4, line: 3814, type: !6, scopeLine: 3815, flags: DIFlagPrototyped | DIFlagAllCallsDescribed, spFlags: DISPFlagDefinition | DISPFlagOptimized, unit: !8, templateParams: !7, retainedNodes: !7)
  !4 = !DIFile(filename: "a", directory: "")
  !5 = !DINamespace(name: "std", scope: null)
  !6 = !DISubroutineType(types: !7)
  !7 = !{}
  !8 = distinct !DICompileUnit(language: DW_LANG_C_plus_plus_14, file: !4, isOptimized: true, runtimeVersion: 0, emissionKind: FullDebug, enums: !7, retainedTypes: !7, globals: !7, imports: !7, splitDebugInlining: false, nameTableKind: None)
  !9 = !DIDerivedType(tag: DW_TAG_pointer_type, baseType: !6, size: 64)
  !10 = !DILocation(line: 0, scope: !3)

the crash is because `use_empty()` doesn't account for metadata uses and eventually we end up with

  define linkonce_odr void @f1() {                                                                                                                                                                   
    call void @llvm.dbg.value(metadata void (i64, %a*)* @f3, metadata !2, metadata !DIExpression()), !dbg !10                                                                                        
    ret void                                                                                                                                                                                         
  }                                                                                                                                                                                                  
                                                                                                                                                                                                     
  declare linkonce_odr void @f3(i64 %t.coerce0, %a* %t.coerce1) comdat                                                                                                                               

and we delete `@f3()` even with the metadata reference


Repository:
  rG LLVM Github Monorepo

CHANGES SINCE LAST ACTION
  https://reviews.llvm.org/D115545/new/

https://reviews.llvm.org/D115545