[llvm] r262035 - [WinEH] Fix funclet return block clobber mask placement

[Reid Kleckner via llvm-commits]

Author: rnk
Date: Fri Feb 26 10:53:19 2016
New Revision: 262035

URL: http://llvm.org/viewvc/llvm-project?rev=262035&view=rev
Log:
[WinEH] Fix funclet return block clobber mask placement

MBB slot index intervals are half open, not closed. getMBBEndIndex()
returns the slot index of the start of the next block in layout order.
Placing a register mask there is incorrect if the successor of the
funclet return is not laid out after the return. Clang generates IR for
catch bodies before generating the following normal code, so we never
noticed this issue until the D frontend authors filed a bug about it.

Instead, we can put the clobber mask on the last instruction of the
funclet return block. We still aren't using a register mask operand on
the CATCHRET instruction because it would cause PEI to spill all CSRs,
including XMM regs, in the prologue.

Fixes PR26679.

Added:
    llvm/trunk/test/CodeGen/X86/catchret-regmask.ll
Modified:
    llvm/trunk/lib/CodeGen/LiveIntervalAnalysis.cpp

Modified: llvm/trunk/lib/CodeGen/LiveIntervalAnalysis.cpp
URL: http://llvm.org/viewvc/llvm-project/llvm/trunk/lib/CodeGen/LiveIntervalAnalysis.cpp?rev=262035&r1=262034&r2=262035&view=diff
==============================================================================
--- llvm/trunk/lib/CodeGen/LiveIntervalAnalysis.cpp (original)
+++ llvm/trunk/lib/CodeGen/LiveIntervalAnalysis.cpp Fri Feb 26 10:53:19 2016
@@ -241,9 +241,13 @@ void LiveIntervals::computeRegMasks() {
       }
     }
 
-    // Some block ends, such as funclet returns, create masks.
+    // Some block ends, such as funclet returns, create masks. Put the mask on
+    // the last instruction of the block, because MBB slot index intervals are
+    // half-open.
     if (const uint32_t *Mask = MBB.getEndClobberMask(TRI)) {
-      RegMaskSlots.push_back(Indexes->getMBBEndIdx(&MBB));
+      assert(!MBB.empty() && "empty return block?");
+      RegMaskSlots.push_back(
+          Indexes->getInstructionIndex(&MBB.back()).getRegSlot());
       RegMaskBits.push_back(Mask);
     }
 

Added: llvm/trunk/test/CodeGen/X86/catchret-regmask.ll
URL: http://llvm.org/viewvc/llvm-project/llvm/trunk/test/CodeGen/X86/catchret-regmask.ll?rev=262035&view=auto
==============================================================================
--- llvm/trunk/test/CodeGen/X86/catchret-regmask.ll (added)
+++ llvm/trunk/test/CodeGen/X86/catchret-regmask.ll Fri Feb 26 10:53:19 2016
@@ -0,0 +1,73 @@
+; RUN: llc < %s | FileCheck %s
+
+target datalayout = "e-m:w-i64:64-f80:128-n8:16:32:64-S128"
+target triple = "x86_64-pc-windows-msvc"
+
+declare i32 @__CxxFrameHandler3(...)
+declare void @throw() noreturn uwtable
+declare i8* @getval()
+
+define i8* @reload_out_of_pad(i8* %arg) #0 personality i32 (...)* @__CxxFrameHandler3 {
+assertPassed:
+  invoke void @throw()
+          to label %unreachable unwind label %catch.dispatch
+
+catch:
+  %cp = catchpad within %cs [i8* null, i32 0, i8* null]
+  catchret from %cp to label %return
+
+  ; This block *must* appear after the catchret to test the bug.
+  ; FIXME: Make this an MIR test so we can control MBB layout.
+unreachable:
+  unreachable
+
+catch.dispatch:
+  %cs = catchswitch within none [label %catch] unwind to caller
+
+return:
+  ret i8* %arg
+}
+
+; CHECK-LABEL: reload_out_of_pad: # @reload_out_of_pad
+; CHECK: movq %rcx, -[[arg_slot:[0-9]+]](%rbp) # 8-byte Spill
+; CHECK: callq throw
+; CHECK: ud2
+; CHECK: movq -[[arg_slot]](%rbp), %rax # 8-byte Reload
+; CHECK: retq
+
+; CHECK: "?catch$3@?0?reload_out_of_pad at 4HA":
+; CHECK-NOT: Reload
+; CHECK: retq
+
+define i8* @spill_in_pad() #0 personality i32 (...)* @__CxxFrameHandler3 {
+assertPassed:
+  invoke void @throw()
+          to label %unreachable unwind label %catch.dispatch
+
+catch:
+  %cp = catchpad within %cs [i8* null, i32 0, i8* null]
+  %val = call i8* @getval() [ "funclet"(token %cp) ]
+  catchret from %cp to label %return
+
+unreachable:
+  unreachable
+
+catch.dispatch:
+  %cs = catchswitch within none [label %catch] unwind to caller
+
+return:
+  ret i8* %val
+}
+
+; CHECK-LABEL: spill_in_pad: # @spill_in_pad
+; CHECK: callq throw
+; CHECK: ud2
+; CHECK: movq -[[val_slot:[0-9]+]](%rbp), %rax # 8-byte Reload
+; CHECK: retq
+
+; CHECK: "?catch$3@?0?spill_in_pad at 4HA":
+; CHECK: callq getval
+; CHECK: movq %rax, -[[val_slot]](%rbp) # 8-byte Spill
+; CHECK: retq
+
+attributes #0 = { uwtable }